1 files changed, 51 insertions, 0 deletions
diff --git a/x11-misc/ccsm/ccsm-0.8.4-r4.ebuild b/x11-misc/ccsm/ccsm-0.8.4-r4.ebuild
new file mode 100644
index 000000000000..9bc964a048b5
--- /dev/null
+++ b/x11-misc/ccsm/ccsm-0.8.4-r4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+DESCRIPTION="Compizconfig Settings Manager"
+HOMEPAGE="http://www.compiz.org/"
+SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/compizconfig-python-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/pygtk-2.12:2[${PYTHON_USEDEP}]
+	gnome-base/librsvg
+"
+
+DOCS=( AUTHORS )
+
+python_prepare_all() {
+	# return error if wrong arguments passed to setup.py
+	sed -i -e 's/raise SystemExit/\0(1)/' setup.py || die 'sed on setup.py failed'
+	# fix desktop file
+	sed -i \
+		-e '/Categories/s/Compiz/X-\0/' \
+		-e '/Encoding/d' \
+		ccsm.desktop.in || die 'sed on ccsm.desktop.in failed'
+
+	# correct gettext behavior
+	if [[ -n "${LINGUAS+x}" ]] ; then
+		for i in $(cd po ; echo *po | sed 's/\.po//g') ; do
+		if ! has ${i} ${LINGUAS} ; then
+			rm po/${i}.po || die
+		fi
+		done
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	#set prefix
+	mydistutilsargs=( build --prefix=/usr )
+}