1 files changed, 63 insertions, 0 deletions
diff --git a/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.36.1-r1.ebuild b/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.36.1-r1.ebuild
new file mode 100644
index 000000000000..73263b8240b2
--- /dev/null
+++ b/x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.36.1-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit gnome2
+
+DESCRIPTION="GNOME default icon theme"
+HOMEPAGE="https://git.gnome.org/browse/adwaita-icon-theme/"
+
+SRC_URI="${SRC_URI}
+	branding? ( https://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
+"
+LICENSE="
+	|| ( LGPL-3 CC-BY-SA-3.0 )
+	branding? ( CC-BY-SA-4.0 )
+"
+SLOT="0"
+IUSE="branding"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+# gtk+:3 is needed for build for the gtk-encode-symbolic-svg utility
+# librsvg is needed for gtk-encode-symbolic-svg to be able to read the source SVG via its pixbuf loader and at runtime for rendering scalable icons shipped by the theme
+RDEPEND="
+	>=x11-themes/hicolor-icon-theme-0.10
+	>=gnome-base/librsvg-2.48:2
+"
+DEPEND="${RDEPEND}
+	x11-libs/gtk+:3
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# This ebuild does not install any binaries
+RESTRICT="binchecks strip"
+
+src_prepare() {
+	if use branding; then
+		for i in 16 22 24 32 48; do
+			cp "${WORKDIR}"/tango-gentoo-v1.1/${i}x${i}/gentoo.png \
+			"${S}"/Adwaita/${i}x${i}/places/start-here.png \
+			|| die "Copying gentoo logos failed"
+		done
+	fi
+
+	# Install cursors in the right place used in Gentoo
+	sed -e 's:^\(cursordir.*\)icons\(.*\):\1cursors/xorg-x11\2:' \
+		-i "${S}"/Makefile.am \
+		-i "${S}"/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# less than 2.45 being a problem is just a guess, but we didn't carry anything between 2.40 and 2.48 in main tree
+	if has_version '<gnome-base/librsvg-2.45:2'; then
+		ewarn "You are building ${CATEGORY}/${PN} against an older"
+		ewarn "gnome-base/librsvg, which will result in various broken symbolic icons until"
+		ewarn "rebuild with newer librsvg, and misrendering of scalable icons at runtime"
+		ewarn "until gnome-base/librsvg is upgraded!"
+	fi
+
+	gnome2_src_configure GTK_UPDATE_ICON_CACHE=$(type -P true)
+}