blob: 7a57fade4cb0aced1964f8e8e0f9176dd75bbef5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..9} )
inherit gnome.org gnome2-utils meson python-any-r1 readme.gentoo-r1 xdg
DESCRIPTION="Archive manager for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/FileRoller"
LICENSE="GPL-2+ CC-BY-SA-3.0"
SLOT="0"
IUSE="libnotify nautilus"
KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
# gdk-pixbuf used extensively in the source
# cairo used in eggtreemultidnd.c
# pango used in fr-window
RDEPEND="
>=app-arch/libarchive-3:=
>=dev-libs/glib-2.38:2
>=dev-libs/json-glib-0.14
>=x11-libs/gtk+-3.22.0:3
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/pango
libnotify? ( >=x11-libs/libnotify-0.4.3:= )
nautilus? ( >=gnome-base/nautilus-3.28.0 )
"
DEPEND="${RDEPEND}"
BDEPEND="
${PYTHON_DEPS}
dev-util/glib-utils
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
${PN} is a frontend for several archiving utilities. If you want a
particular archive format support, see ${HOMEPAGE}
and install the relevant package. For example:
7-zip - app-arch/p7zip
ace - app-arch/unace
arj - app-arch/arj
brotli - app-arch/brotli
cpio - app-arch/cpio
deb - app-arch/dpkg
iso - app-cdr/cdrtools
jar,zip - app-arch/zip and app-arch/unzip
lha - app-arch/lha
lzop - app-arch/lzop
lz4 - app-arch/lz4
rar - app-arch/unrar or app-arch/unar
rpm - app-arch/rpm
unstuff - app-arch/stuffit
zstd - app-arch/zstd
zoo - app-arch/zoo"
src_prepare() {
# File providing Gentoo package names for various archivers
cp -v "${FILESDIR}"/3.36-packages.match data/packages.match || die
xdg_src_prepare
}
src_configure() {
local emesonargs=(
-Drun-in-place=false
$(meson_use nautilus nautilus-actions)
$(meson_use libnotify notification)
-Dpackagekit=false
-Dlibarchive=true
)
meson_src_configure
}
src_install() {
meson_src_install
readme.gentoo_create_doc
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
readme.gentoo_print_elog
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb