blob: c3e917afd7fe67a267c56e60ae47137b9d05bcab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake-utils xdg-utils
DESCRIPTION="Vim-fork focused on extensibility and agility."
HOMEPAGE="https://neovim.io"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/neovim/neovim.git"
else
SRC_URI="https://github.com/neovim/neovim/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~x86"
fi
LICENSE="Apache-2.0 vim"
SLOT="0"
IUSE="+clipboard +luajit +nvimpager python remote ruby +tui +jemalloc"
CDEPEND="
dev-libs/libuv:0=
dev-libs/msgpack:0=
luajit? ( dev-lang/luajit:2 )
!luajit? (
dev-lang/lua:=
dev-lua/LuaBitOp
)
tui? (
dev-libs/libtermkey
>=dev-libs/unibilium-2.0.0:0=
)
dev-libs/libvterm
dev-lua/lpeg[luajit=]
dev-lua/mpack[luajit=]
jemalloc? ( dev-libs/jemalloc )
net-libs/libnsl"
DEPEND="
${CDEPEND}
dev-util/gperf
virtual/libintl
virtual/libiconv
app-eselect/eselect-vi"
RDEPEND="
${CDEPEND}
python? ( dev-python/neovim-python-client )
ruby? ( dev-ruby/neovim-ruby-client )
remote? ( dev-python/neovim-remote )
clipboard? ( || ( x11-misc/xsel x11-misc/xclip ) )"
CMAKE_BUILD_TYPE=Release
src_prepare() {
# use our system vim dir
sed -e '/^# define SYS_VIMRC_FILE/s|$VIM|'"${EPREFIX}"'/etc/vim|' \
-i src/nvim/globals.h || die
# add eclass to bash filetypes
sed -e 's|*.ebuild|*.ebuild,*.eclass|' -i runtime/filetype.vim || die
cmake-utils_src_prepare
}
src_configure() {
local mycmakeargs=(
-DFEAT_TUI=$(usex tui)
-DENABLE_JEMALLOC=$(usex jemalloc)
-DPREFER_LUA=$(usex luajit no yes)
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
# install a default configuration file
insinto /etc/vim
doins "${FILESDIR}"/sysinit.vim
# conditionally install a symlink for nvimpager
if use nvimpager; then
dosym ../share/nvim/runtime/macros/less.sh /usr/bin/nvimpager
fi
}
pkg_postinst() {
xdg_desktop_database_update
}
pkg_postrm() {
xdg_desktop_database_update
}
|
GitWeb