app-emacs/cask/cask-0.9.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit elisp

DESCRIPTION="Project management for Emacs package development"
HOMEPAGE="https://github.com/cask/cask/"

if [[ "${PV}" == *9999* ]] ; then
	inherit git-r3

	EGIT_REPO_URI="https://github.com/cask/${PN}"
else
	SRC_URI="https://github.com/cask/${PN}/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz"

	KEYWORDS="~amd64 ~x86"
fi

LICENSE="GPL-3+"
SLOT="0"
RESTRICT="test"  # Most tests fail.

RDEPEND="
	app-emacs/ansi
	app-emacs/commander
	app-emacs/epl
	app-emacs/f
	app-emacs/package-build
	app-emacs/s
	app-emacs/shut-up
"
BDEPEND="
	${RDEPEND}
"

PATCHES=(
	"${FILESDIR}/cask-0.9.0-bin-launcher-fix.patch"
	"${FILESDIR}/cask-0.9.0-home-dir.patch"
	"${FILESDIR}/cask-no-bootstrap.patch"
)
ELISP_REMOVE="
	${PN}-bootstrap.el
"

DOCS=( README.org cask_small.png )
SITEFILE="50${PN}-gentoo.el"

src_prepare() {
	elisp_src_prepare

	sed "s|@SITELISP@|${EPREFIX}${SITELISP}/${PN}|" -i "./bin/${PN}" || die
}

src_install() {
	elisp_src_install

	exeinto /usr/bin
	doexe "./bin/${PN}"
}