blob: 03142f16ead5898f2b3aab412e2b2784a0c3c776 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake readme.gentoo-r1
DESCRIPTION="Friendly Interactive SHell"
HOMEPAGE="http://fishshell.com/"
MY_PV="${PV/_beta/b}"
MY_P="${PN}-${MY_PV}"
if [[ ${PV} == "9999" ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/${PN}-shell/${PN}-shell.git"
else
SRC_URI="https://github.com/${PN}-shell/${PN}-shell/releases/download/${MY_PV}/${MY_P}.tar.gz"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="doc nls test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/libpcre2-10.21[pcre32]
sys-devel/bc
sys-libs/ncurses:0=[unicode]
"
DEPEND="${RDEPEND}
doc? ( app-doc/doxygen )
nls? ( sys-devel/gettext )
test? ( dev-tcltk/expect )
"
PATCHES=( "${FILESDIR}/fix-histfile-test-on-ppc.patch" )
S="${WORKDIR}/${MY_P}"
src_prepare() {
# workaround for https://github.com/fish-shell/fish-shell/issues/4883
sed -i 's#${TEST_INSTALL_DIR}/${CMAKE_INSTALL_PREFIX}#${TEST_INSTALL_DIR}#' \
cmake/Tests.cmake || die
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DCMAKE_INSTALL_BINDIR="${EPREFIX}/bin"
-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
-DCURSES_NEED_NCURSES=ON
-DINTERNAL_WCWIDTH=OFF
-DBUILD_DOCS="$(usex doc)"
-DWITH_GETTEXT="$(usex nls)"
)
cmake_src_configure
}
src_install() {
cmake_src_install
keepdir /usr/share/fish/vendor_{completions,conf,functions}.d
readme.gentoo_create_doc
}
src_test() {
cmake_build -j1 test
}
pkg_postinst() {
readme.gentoo_print_elog
}
|
GitWeb
