dev-java/backport-util-concurrent/backport-util-concurrent-3.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5
JAVA_PKG_IUSE="doc source test"

inherit java-pkg-2 java-ant-2

SF_PN="backport-jsr166"
MY_P="${PN}-Java60-${PV}"

DESCRIPTION="A portability wrapper for java.util.concurrent API (jsr166) 6.0"
HOMEPAGE="http://${SF_PN}.sourceforge.net/"
SRC_URI="mirror://sourceforge/${SF_PN}/${PV}/${MY_P}-src.tar.bz2"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-macos"
IUSE=""

DEPEND=">=virtual/jdk-1.6
	test? (
		dev-java/junit:0
		)
	app-arch/unzip"
RDEPEND=">=virtual/jre-1.6"

S="${WORKDIR}/${MY_P}-src"

java_prepare() {
	if use test; then
		# make test not depend on make
		epatch "${FILESDIR}/${PN}-3.0-test.patch"
	else
		# don't compile test classes
		epatch "${FILESDIR}/${PN}-3.0-notest.patch"
	fi

	cd "${S}/external" || die
	rm -v *.jar || die

	use test && java-pkg_jar-from --build-only junit
}

EANT_BUILD_TARGET="javacompile archive"
EANT_TEST_TARGET="test"

src_install() {
	java-pkg_dojar ${PN}.jar
	dohtml README.html || die

	use doc && java-pkg_dojavadoc doc/api
	use source && java-pkg_dosrc src/*
}