blob: fe79e806cfadfa71a78ba33e6c6eb2a7049e072b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_OPTIONAL=1
PYTHON_COMPAT=( python3_{9..11} )
inherit cmake distutils-r1 toolchain-funcs
DESCRIPTION="disassembly/disassembler framework + bindings"
HOMEPAGE="https://www.capstone-engine.org/"
SRC_URI="https://github.com/capstone-engine/capstone/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0/5" # libcapstone.so.5
KEYWORDS="amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv x86"
IUSE="python test"
RDEPEND="python? ( ${PYTHON_DEPS} )"
DEPEND="${RDEPEND}
python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
distutils_enable_tests setup.py
S=${WORKDIR}/${P/_rc/-rc}
PATCHES=(
"${FILESDIR}"/${P}-pkgconfig.patch
"${FILESDIR}"/${P}-oob-mem-access.patch
)
if [[ ${PV} == *_rc* ]]; then
# Upstream doesn't flag release candidates (bug 858350)
QA_PKGCONFIG_VERSION=""
fi
wrap_python() {
local phase=$1
shift
if use python; then
pushd bindings/python >/dev/null || die
distutils-r1_${phase} "$@"
popd >/dev/null || die
fi
}
src_prepare() {
tc-export RANLIB
cmake_src_prepare
wrap_python ${FUNCNAME}
}
src_configure() {
local mycmakeargs=(
-DCAPSTONE_BUILD_TESTS="$(usex test)"
)
cmake_src_configure
wrap_python ${FUNCNAME}
}
src_compile() {
cmake_src_compile
wrap_python ${FUNCNAME}
}
src_test() {
cmake_src_test
wrap_python ${FUNCNAME}
}
src_install() {
cmake_src_install
wrap_python ${FUNCNAME}
}
|
GitWeb