blob: 84be8f1ddd9e04a814bb24bf191f8ac0153d1e03 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} )
inherit autotools python-r1
DESCRIPTION="Tiny library providing a C \"class\" for working with arbitrary big sizes in bytes"
HOMEPAGE="https://github.com/storaged-project/libbytesize"
SRC_URI="https://github.com/storaged-project/libbytesize/releases/download/${PV}/${P}.tar.gz"
LICENSE="LGPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="doc python test tools"
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
tools? ( python )
"
RDEPEND="
dev-libs/gmp:0=
dev-libs/mpfr:=
dev-libs/libpcre2
python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
BDEPEND="
sys-devel/gettext
doc? ( dev-util/gtk-doc )
test? (
dev-python/pocketlint[${PYTHON_USEDEP}]
dev-python/polib[${PYTHON_USEDEP}]
)
"
DOCS=( README.md )
RESTRICT="test"
PATCHES=(
"${FILESDIR}/${PN}-2.4-no_Werror.patch"
"${FILESDIR}/${PN}-2.6-configure-bashism.patch"
)
python_do() {
if use python; then
python_foreach_impl run_in_build_dir "$@"
else
"$@"
fi
}
src_prepare() {
default
eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_with doc gtk-doc)
$(use_with python python3)
$(use_with tools)
)
local ECONF_SOURCE="${S}"
python_do econf "${myeconfargs[@]}"
}
src_compile() {
python_do emake
}
src_test() {
python_do emake check
}
install_helper() {
emake DESTDIR="${D}" install
use python && python_optimize
}
src_install() {
python_do install_helper
einstalldocs
find "${ED}" -name "*.la" -type f -delete || die
}
|
GitWeb