blob: 3fc06ee2e3d4d1fa3fb24e4cb2a486d80c00cf67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit gnome2 flag-o-matic multilib-minimal
DESCRIPTION="Typesafe callback system for standard C++"
HOMEPAGE="http://libsigc.sourceforge.net/"
LICENSE="LGPL-2.1+"
SLOT="2"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc static-libs test"
RDEPEND=""
DEPEND="sys-devel/m4
doc? ( app-doc/doxygen )
test? ( dev-libs/boost[${MULTILIB_USEDEP}] )"
# Needs mm-common for eautoreconf
src_prepare() {
# properly interpret --{enable,disable}-benchmark configure option (bug 599764)
eapply "${FILESDIR}"/${P}-make-disable-benchmarks-work.patch
# don't waste time building examples
sed -i 's|^\(SUBDIRS =.*\)examples\(.*\)$|\1\2|' \
Makefile.am Makefile.in || die "sed examples failed"
# don't waste time building tests unless USE=test
if ! use test ; then
sed -i 's|^\(SUBDIRS =.*\)tests\(.*\)$|\1\2|' \
Makefile.am Makefile.in || die "sed tests failed"
fi
gnome2_src_prepare
}
multilib_src_configure() {
filter-flags -fno-exceptions #84263
ECONF_SOURCE="${S}" gnome2_src_configure \
$(multilib_native_use_enable doc documentation) \
$(use_enable static-libs static) \
$(use_enable test benchmark)
}
multilib_src_install() {
gnome2_src_install
}
multilib_src_install_all() {
einstalldocs
# Note: html docs are installed into /usr/share/doc/libsigc++-2.0
# We can't use /usr/share/doc/${PF} because of links from glibmm etc. docs
use doc && dodoc -r examples
}
|
GitWeb
