blob: 414c31fe69cf3b4e77a860011e6dce5a53b83293 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..3} luajit )
MY_P="${PN}-rel-${PV}"
inherit lua toolchain-funcs
DESCRIPTION="Most comprehensive OpenSSL module in the Lua universe"
HOMEPAGE="https://github.com/wahern/luaossl"
SRC_URI="https://github.com/wahern/${PN}/archive/rel-${PV}.tar.gz -> ${MY_P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
IUSE="examples"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RDEPEND="
dev-libs/openssl:0[-bindist]
!dev-lua/luacrypto
!dev-lua/lua-openssl
!dev-lua/luasec
${LUA_DEPS}
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( "doc/." )
src_prepare() {
default
# Remove Lua autodetection
# Respect users CFLAGS
sed -e '/LUAPATH :=/d' -e '/LUAPATH_FN =/d' -e '/HAVE_API_FN =/d' -e '/WITH_API_FN/d' -e 's/-O2//g' -i GNUmakefile || die
lua_copy_sources
}
lua_src_compile() {
pushd "${BUILD_DIR}" || die
if [[ ${ELUA} != luajit ]]; then
LUA_VERSION="$(ver_cut 1-2 $(lua_get_version))"
else
# This is a workaround for luajit, as it confirms to lua5.1
# and the 'GNUmakefile' doesn't understand LuaJITs version.
LUA_VERSION="5.1"
fi
local myemakeargs=(
"CC=$(tc-getCC)"
"ALL_CPPFLAGS=${CPPFLAGS} $(lua_get_CFLAGS)"
"libdir="
)
emake "${myemakeargs[@]}" openssl${LUA_VERSION}
popd
}
src_compile() {
lua_foreach_impl lua_src_compile
}
lua_src_install() {
pushd "${BUILD_DIR}" || die
if [[ ${ELUA} != luajit ]]; then
LUA_VERSION="$(ver_cut 1-2 $(lua_get_version))"
else
# This is a workaround for luajit, as it confirms to lua5.1
# and the 'GNUmakefile' doesn't understand LuaJITs version.
LUA_VERSION="5.1"
fi
local myemakeargs=(
"DESTDIR=${D}"
"lua${LUA_VERSION/./}cpath=$(lua_get_cmod_dir)"
"lua${LUA_VERSION/./}path=$(lua_get_lmod_dir)"
"prefix=${EPREFIX}/usr"
)
emake "${myemakeargs[@]}" install${LUA_VERSION}
popd
}
src_install() {
lua_foreach_impl lua_src_install
use examples && dodoc -r "examples/."
einstalldocs
}
|
GitWeb