blob: 62a32d0c6c577df81e04e59c06067197beb60854 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 multiprocessing
DESCRIPTION="Composable complex class support for attrs and dataclasses"
HOMEPAGE="
https://pypi.org/project/cattrs/
https://github.com/python-attrs/cattrs/
"
SRC_URI="
https://github.com/python-attrs/cattrs/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~hppa ~loong ~ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="test-rust"
RDEPEND="
>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/exceptiongroup[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
' 3.{9..10})
"
BDEPEND="
test? (
>=dev-python/cbor2-5.4.6[${PYTHON_USEDEP}]
>=dev-python/hypothesis-6.54.5[${PYTHON_USEDEP}]
>=dev-python/immutables-0.18[${PYTHON_USEDEP}]
>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
>=dev-python/pymongo-4.2.0[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
>=dev-python/tomlkit-0.11.4[${PYTHON_USEDEP}]
>=dev-python/ujson-5.4.0[${PYTHON_USEDEP}]
test-rust? (
>=dev-python/orjson-3.5.2[${PYTHON_USEDEP}]
)
)
"
distutils_enable_tests pytest
src_prepare() {
local PATCHES=(
# https://github.com/python-attrs/cattrs/pull/415
"${FILESDIR}/${P}-32bit-time_t.patch"
)
sed -e 's:--benchmark.*::' \
-e '/addopts/d' \
-i pyproject.toml || die
distutils-r1_src_prepare
}
python_test() {
local EPYTEST_DESELECT=()
if ! has_version "dev-python/orjson[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
tests/test_preconf.py::test_orjson
tests/test_preconf.py::test_orjson_converter
tests/test_preconf.py::test_orjson_converter_unstruct_collection_overrides
)
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p xdist -n "$(makeopts_jobs)" tests
}
|
GitWeb
