blob: 2046409d2aeb268395562c6357aa158735e5249f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{8..11} )
inherit distutils-r1
DESCRIPTION="Various LDAP-related Python modules"
HOMEPAGE="https://www.python-ldap.org/en/latest/
https://pypi.org/project/python-ldap/
https://github.com/python-ldap/python-ldap"
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://github.com/python-ldap/python-ldap.git"
inherit git-r3
else
# Snapshot for various new OpenLDAP fixes, bug #835637
# (There were a bunch of followup commits and general other
# serious bugfixes we want.)
MY_COMMIT="7f30c4721ea2ca4373ed7860e6467781f0afa758"
#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
SRC_URI="https://github.com/python-ldap/python-ldap/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"/${PN}-${MY_COMMIT}
KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ppc64 ~riscv ~sparc x86 ~x86-solaris"
fi
LICENSE="MIT PSF-2"
SLOT="0"
IUSE="examples sasl ssl"
RDEPEND="
>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
net-nds/openldap:=[sasl?,ssl?]
"
# We do not link against cyrus-sasl but we use some
# of its headers during the build.
DEPEND="
net-nds/openldap:=[sasl?,ssl?]
sasl? ( >=dev-libs/cyrus-sasl-2.1 )
"
distutils_enable_tests pytest
distutils_enable_sphinx Doc
python_prepare_all() {
# The live ebuild won't compile if setuptools_scm < 1.16.2 is installed
# https://github.com/pypa/setuptools_scm/issues/228
if [[ ${PV} == *9999* ]]; then
rm -r .git || die
fi
if ! use sasl; then
sed -i 's/HAVE_SASL//g' setup.cfg || die
fi
if ! use ssl; then
sed -i 's/HAVE_TLS//g' setup.cfg || die
fi
distutils-r1_python_prepare_all
}
python_test() {
# Run all tests which don't require slapd
local EPYTEST_IGNORE=(
t_bind.py
t_cext.py
t_edit.py
t_ldapobject.py
t_ldap_options.py
t_ldap_sasl.py
t_ldap_schema_subentry.py
t_ldap_syncrepl.py
t_slapdobject.py
)
pushd Tests >/dev/null || die
epytest
popd > /dev/null || die
}
python_install() {
distutils-r1_python_install
python_optimize
}
python_install_all() {
if use examples; then
docinto examples
dodoc -r Demo/.
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}
|
GitWeb