blob: 9a719320744e706c8a697cf507bffa09025727bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_11 )
inherit distutils-r1
DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
HOMEPAGE="
https://python-rq.org/
https://github.com/rq/rq/
https://pypi.org/project/rq/
"
# Tests missing from sdist, as of 1.14.1
SRC_URI="
https://github.com/rq/rq/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 ~riscv ~sparc x86"
RDEPEND="
>=dev-python/click-5.0[${PYTHON_USEDEP}]
>=dev-python/redis-4.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-db/redis
dev-python/psutil[${PYTHON_USEDEP}]
dev-python/sentry-sdk[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_test() {
local redis_pid="${T}"/redis.pid
local redis_port=6379
local redis_test_config="daemonize yes
pidfile ${redis_pid}
port ${redis_port}
bind 127.0.0.1
"
# Spawn Redis itself for testing purposes
# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
einfo "Spawning Redis"
einfo "NOTE: Port ${redis_port} must be free"
/usr/sbin/redis-server - <<< "${redis_test_config}" || die
# Run the actual tests
distutils-r1_src_test
# Clean up afterwards
kill "$(<"${redis_pid}")" || die
}
|
GitWeb
