blob: 2d38cb13c9955bdbd68dac3275b7240f86576ea3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
USE_RUBY="ruby27 ruby30 ruby31 ruby32"
RUBY_FAKEGEM_RECIPE_DOC=""
RUBY_FAKEGEM_DOCDIR=""
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_GEMSPEC="activestorage.gemspec"
RUBY_FAKEGEM_EXTRAINSTALL="app config db"
RUBY_FAKEGEM_BINWRAP=""
inherit ruby-fakegem
DESCRIPTION="Attach cloud and local files in Rails applications"
HOMEPAGE="https://github.com/rails/rails"
SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
LICENSE="MIT"
SLOT="$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE=""
RUBY_S="rails-${PV}/${PN}"
DEPEND+=" test? ( app-text/mupdf media-gfx/imagemagick[jpeg,png,tiff] media-video/ffmpeg app-text/poppler[utils] ) "
ruby_add_rdepend "
~dev-ruby/actionpack-${PV}:*
~dev-ruby/activejob-${PV}:*
~dev-ruby/activerecord-${PV}:*
~dev-ruby/activesupport-${PV}:*
dev-ruby/marcel:1.0
>=dev-ruby/mini_mime-1.1.0
"
ruby_add_bdepend "
test? (
~dev-ruby/railties-${PV}
>=dev-ruby/image_processing-1.2:0
=dev-ruby/minitest-5.15*:*
dev-ruby/mini_magick
dev-ruby/mocha
dev-ruby/rake
dev-ruby/sprockets-rails
dev-ruby/sqlite3
)"
all_ruby_prepare() {
# Remove items from the common Gemfile that we don't need for this
# test run. This also requires handling some gemspecs.
sed -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|execjs\|jquery-rails\|'mysql'\|journey\|ruby-prof\|stackprof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|redcarpet\|bcrypt\|uglifier\|aws-sdk-s3\|aws-sdk-sns\|google-cloud-storage\|azure-storage\|blade\|bootsnap\|hiredis\|qunit-selenium\|chromedriver-helper\|redis\|rb-inotify\|stackprof\|websocket-client-simple\|libxml-ruby\|sass-rails\|capybara\|rack-cache\|selenium\|dalli\|listen\|connection_pool\|puma\|mysql2\|webdrivers\|webpacker\|rexml\|webmock\|webrick\|propshaft\|sprockets-export\|rack-test\|terser\)/ s:^:#:" \
-e '/stimulus-rails/,/tailwindcss-rails/ s:^:#:' \
-e '/group :\(doc\|job\|rubocop\|test\)/,/^end/ s:^:#:' \
-i ../Gemfile || die
rm ../Gemfile.lock || die
# Use mini_magick since vips is not packaged on Gentoo
sed -i -e '/mini_magick/aActiveStorage.variant_processor = :mini_magick' test/test_helper.rb || die
# Avoid vips-specific tests
sed -i -e '/\(resized and monochrome variation of JPEG blob\|monochrome with default variant_processor\|disabled variation of JPEG blob\)/askip "No vips support"' test/models/variant_test.rb || die
}
|
GitWeb
