dev-ruby/escape_utils/escape_utils-1.2.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5

# ruby25 -> code not compatible
USE_RUBY="ruby23 ruby24"

RUBY_FAKEGEM_RECIPE_TEST=""
RUBY_FAKEGEM_RECIPE_DOC=""

inherit ruby-fakegem

DESCRIPTION="Faster string escaping routines for your ruby apps"
HOMEPAGE="https://github.com/brianmario/escape_utils"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"

all_ruby_prepare() {
	sed -i -e "/bundler/d" test/helper.rb || die
}

each_ruby_configure() {
	${RUBY} -Cext/escape_utils extconf.rb || die
}

each_ruby_compile() {
	emake V=1 -Cext/escape_utils
	cp ext/escape_utils/escape_utils$(get_modname) lib/escape_utils || die
}

each_ruby_test() {
	${RUBY} -Ilib:test:. -e "Dir['test/**/*_test.rb'].each {|f| require f}" || die
}