dev-tcltk/tktray/tktray-1.3.9-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

DESCRIPTION="System Tray Icon Support for Tk on X11"
HOMEPAGE="https://code.google.com/p/tktray/"
SRC_URI="https://tktray.googlecode.com/files/${PN}${PV}.tar.gz"
S="${WORKDIR}/${PN}${PV}"

LICENSE="tcltk"
SLOT="0"
KEYWORDS="amd64 ~ppc ~sparc x86"
IUSE="debug threads"

# tests need actual X server with user interaction, bug #284919
RESTRICT="test"

DEPEND="
	>=dev-lang/tcl-8.4:=
	>=dev-lang/tk-8.4:=
	x11-libs/libXext"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}"/1.1-ldflags.patch
)

src_prepare() {
	default

	# Fix bad configure tests w/ Clang 16
	eautoreconf
}

src_configure() {
	source "${ESYSROOT}/usr/$(get_libdir)/tclConfig.sh" || die

	CPPFLAGS="-I${TCL_SRC_DIR}/generic ${CPPFLAGS}" \
	econf \
		$(use_enable debug symbols) \
		$(use_enable threads)
}