dev-util/clippy/clippy-8.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright 2020-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

MY_P="frr-${PV}"
PYTHON_COMPAT=( python3_{8..10} )
inherit autotools python-single-r1

DESCRIPTION="Standalone clippy tool built from FRR sources"
HOMEPAGE="https://frrouting.org/"
SRC_URI="https://github.com/FRRouting/frr/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/frr-${MY_P}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~arm64 x86"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

# standalone clippy does not have any tests
# restrict to prevent bug 811753
RESTRICT="test"

DEPEND="
	${PYTHON_DEPS}
	virtual/libelf:=
"
RDEPEND="${DEPEND}"
BDEPEND="sys-devel/flex"

PATCHES=(
	"${FILESDIR}"/${P}-big-endian.patch
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf --enable-clippy-only
}

src_install() {
	dobin lib/clippy
}