blob: 010c9faf988d52ff0c1a3c2064f420792bd422d2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit cdrom estack desktop wrapper xdg
DESCRIPTION="The Curse of Monkey Island, the third game in the series"
HOMEPAGE="https://en.wikipedia.org/wiki/The_Curse_of_Monkey_Island"
SRC_URI="https://dev.gentoo.org/~chewi/distfiles/${PN}.jpg"
LICENSE="comi"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
RESTRICT="bindist"
RDEPEND=">=games-engines/scummvm-0.4.0"
S="${WORKDIR}"
dotar() {
cd "${CDROM_ABSMATCH%/*}" || die
eshopts_push -s nocaseglob nullglob
# Lowercase
# Documentation into doc
# Remainder into data
# Avoid copying files twice
tar c \
--mode=u+w \
--ignore-case \
--xform='s:^[^a-z]+$:\L\0:x' \
--xform='s:.*:data/\0:x' \
--xform='s:.*\.(pdf|txt)$:doc/\0:x' \
--xform='s:^doc/data/:doc/:x' \
--exclude="$(use doc || echo '*.pdf')" \
--exclude-from=<(find "${WORKDIR}"/data -type f -printf "%P\n" 2>/dev/null) \
*.{txt,pdf} *.la[0-9] resource*/ \
| tar x -C "${WORKDIR}"
assert "tar failed"
eshopts_pop
# Don't prevent CD ejection.
cd "${WORKDIR}" || die
}
src_unpack() {
cdrom_get_cds comi.la1 comi.la2
dotar
cdrom_load_next_cd
dotar
}
src_install() {
insinto /usr/share/games/scummvm/games/comi
doins -r data/*
# Documentation may be missing.
[[ -d doc ]] && dodoc doc/*
doicon "${DISTDIR}"/${PN}.jpg
make_wrapper ${PN} "scummvm comi"
make_desktop_entry ${PN} "The Curse of Monkey Island" ${PN}.jpg
}
|
GitWeb
