blob: 470a939e83aa6733ff7e4aa13891474b59a5454e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org meson xdg vala virtualx
DESCRIPTION="Building blocks for modern adaptive GNOME apps"
HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
LICENSE="LGPL-2.1+"
SLOT="1"
KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86"
IUSE="examples glade gtk-doc +introspection test +vala"
REQUIRED_USE="
gtk-doc? ( introspection )
vala? ( introspection )
"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.44:2
>=x11-libs/gtk+-3.24.1:3[introspection?]
glade? ( dev-util/glade:3.10= )
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}
x11-base/xorg-proto"
BDEPEND="
dev-libs/libxml2:2
dev-util/glib-utils
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
gtk-doc? ( >=dev-util/gi-docgen-2021.1
app-text/docbook-xml-dtd:4.3 )
vala? ( $(vala_depend) )
"
src_prepare() {
default
use vala && vala_setup
xdg_environment_reset
}
src_configure() {
local emesonargs=(
-Dprofiling=false # -pg passing
$(meson_feature introspection)
$(meson_use vala vapi)
$(meson_use gtk-doc gtk_doc)
$(meson_use test tests)
$(meson_use examples)
$(meson_feature glade glade_catalog)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
|
GitWeb
