blob: 2a7a81060a7ca7b2b5fc3e65cca4032b3936fabf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit cmake-utils eapi7-ver
DESCRIPTION="LXQt desktop panel and plugins"
HOMEPAGE="https://lxqt.org/"
MY_PV="$(ver_cut 1-2)*"
if [[ ${PV} = *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
else
SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
KEYWORDS="amd64 ~arm ~arm64 x86"
fi
LICENSE="LGPL-2.1+"
SLOT="0"
IUSE="+alsa clock colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator +mainmenu
+mount networkmonitor pulseaudio +quicklaunch sensors +showdesktop
+spacer statusnotifier sysstat +taskbar +tray +volume +worldclock"
REQUIRED_USE="
|| ( desktopswitch mainmenu showdesktop taskbar )
volume? ( || ( alsa pulseaudio ) )
"
RDEPEND="
>=dev-libs/libqtxdg-3.0.0
dev-qt/qtcore:5
dev-qt/qtdbus:5
dev-qt/qtgui:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
dev-qt/qtx11extras:5
dev-qt/qtxml:5
kde-frameworks/kwindowsystem:5[X]
>=lxde-base/lxmenu-data-0.1.5
>=lxde-base/menu-cache-1.1.0
=lxqt-base/liblxqt-${MY_PV}
=lxqt-base/lxqt-globalkeys-${MY_PV}
x11-libs/libX11
cpuload? ( sys-libs/libstatgrab )
kbindicator? ( x11-libs/libxkbcommon )
mount? ( kde-frameworks/solid:5 )
networkmonitor? ( sys-libs/libstatgrab )
sensors? ( sys-apps/lm_sensors )
statusnotifier? ( dev-libs/libdbusmenu-qt[qt5(+)] )
sysstat? ( >=lxqt-base/libsysstat-0.4.1 )
tray? (
x11-libs/libxcb:=
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXrender
x11-libs/xcb-util
)
volume? (
alsa? ( media-libs/alsa-lib )
pulseaudio? (
media-sound/pavucontrol-qt
media-sound/pulseaudio
)
)
!lxqt-base/lxqt-common
"
DEPEND="${RDEPEND}
dev-qt/linguist-tools:5
>=dev-util/lxqt-build-tools-0.5.0
virtual/pkgconfig
"
src_configure() {
local mycmakeargs=(
-DPULL_TRANSLATIONS=OFF
# Plugins
-DCLOCK_PLUGIN=$(usex clock)
-DCOLORPICKER_PLUGIN=$(usex colorpicker)
-DCPULOAD_PLUGIN=$(usex cpuload)
-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
-DDOM_PLUGIN=$(usex dom)
-DKBINDICATOR_PLUGIN=$(usex kbindicator)
-DMAINMENU_PLUGIN=$(usex mainmenu)
-DMOUNT_PLUGIN=$(usex mount)
-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
-DSENSORS_PLUGIN=$(usex sensors)
-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
-DSPACER_PLUGIN=$(usex spacer)
-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
-DSYSSTAT_PLUGIN=$(usex sysstat)
-DTASKBAR_PLUGIN=$(usex taskbar)
-DTRAY_PLUGIN=$(usex tray)
-DVOLUME_PLUGIN=$(usex volume)
-DWORLDCLOCK_PLUGIN=$(usex worldclock)
)
if use volume; then
mycmakeargs+=(
-DVOLUME_USE_ALSA=$(usex alsa)
-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
)
fi
cmake-utils_src_configure
}
src_install(){
cmake-utils_src_install
doman panel/man/*.1
}
|
GitWeb