blob: 6bd3d6db745517c35f3ec3a3ba1c37f5d1296c22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
if [[ ${PV} = *9999* ]]; then
EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
GIT_ECLASS="git-r3"
else
SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/raw/website/files/release/${P}/${P}.tar.xz"
KEYWORDS="amd64 arm ~arm64 ~ppc ~ppc64 x86"
fi
inherit meson multilib-minimal ${GIT_ECLASS}
DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
LICENSE="BSD-2"
SLOT="0"
IUSE="doc +egl +gbm wayland X"
RESTRICT="test" # gl_basic tests don't work when run from portage
RDEPEND="
>=media-libs/mesa-9.1.6[egl?,gbm?,${MULTILIB_USEDEP}]
>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}
>=x11-base/xcb-proto-1.8-r3[${MULTILIB_USEDEP}]
"
BDEPEND="
dev-libs/libxslt
app-text/docbook-xml-dtd:4.2
"
PATCHES=(
"${FILESDIR}"/${PN}-1.6.0-meson-Generate-cmake-config-and-version-files-if-mes.patch
)
MULTILIB_CHOST_TOOLS=(
/usr/bin/wflinfo$(get_exeext)
)
multilib_src_configure() {
local emesonargs=(
$(meson_feature X glx)
$(meson_feature wayland)
$(meson_feature X x11_egl)
$(meson_feature gbm)
$(meson_feature egl surfaceless_egl)
-Dbuild-manpages=true
-Dbuild-tests=false
)
meson_src_configure
}
multilib_src_compile() {
meson_src_compile
}
multilib_src_install() {
meson_src_install
! use doc && rm -rf "${D}"/usr/share/doc/waffle1
}
|
GitWeb
