blob: d17fb05439f356b0083e0e2162a20ed421523810 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# TODO: Add python support.
EAPI=8
inherit autotools multilib-minimal
DESCRIPTION="HTTP/2 C Library"
HOMEPAGE="https://nghttp2.org/"
SRC_URI="https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz
https://dev.gentoo.org/~voyageur/distfiles/${PN}-1.51.0-pthread.patch"
LICENSE="MIT"
SLOT="0/1.14" # <C++>.<C> SONAMEs
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="cxx debug hpack-tools jemalloc static-libs systemd test utils xml"
RESTRICT="!test? ( test )"
SSL_DEPEND="
>=dev-libs/openssl-1.0.2:0=[-bindist(-),${MULTILIB_USEDEP}]
"
RDEPEND="
cxx? (
${SSL_DEPEND}
dev-libs/boost:=[${MULTILIB_USEDEP}]
)
hpack-tools? ( >=dev-libs/jansson-2.5:= )
jemalloc? ( dev-libs/jemalloc:=[${MULTILIB_USEDEP}] )
utils? (
${SSL_DEPEND}
>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
>=sys-libs/zlib-1.2.3[${MULTILIB_USEDEP}]
net-dns/c-ares:=[${MULTILIB_USEDEP}]
)
systemd? ( sys-apps/systemd )
xml? ( >=dev-libs/libxml2-2.7.7:2[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${DISTDIR}"/${PN}-1.51.0-pthread.patch
)
src_prepare() {
default
eautoreconf
}
multilib_src_configure() {
local myeconfargs=(
--disable-examples
--disable-failmalloc
--disable-python-bindings
--disable-werror
--enable-threads
--without-cython
$(use_enable cxx asio-lib)
$(use_enable debug)
$(multilib_native_use_enable hpack-tools)
$(multilib_native_use_with hpack-tools jansson)
$(multilib_native_use_with jemalloc)
$(use_enable static-libs static)
$(multilib_native_use_with systemd)
$(use_with test cunit)
$(multilib_native_use_enable utils app)
$(multilib_native_use_with xml libxml2)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
if ! use static-libs ; then
find "${ED}"/usr -type f -name '*.la' -delete || die
fi
}
|
GitWeb