blob: 579c65b8d16b580fc79da542aa112aebf6e80281 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit cmake-utils eutils gnome2-utils
MY_PV="${PV//_rc/-rcgit.}"
DESCRIPTION="A GTK+ RDP, VNC, XDMCP and SSH client"
HOMEPAGE="http://remmina.org/"
SRC_URI="https://github.com/FreeRDP/Remmina/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ayatana crypt freerdp gnome-keyring nls spice ssh telepathy webkit zeroconf"
RDEPEND="
dev-libs/glib:2
net-libs/libvncserver
x11-libs/libxkbfile
x11-libs/gdk-pixbuf
x11-libs/gtk+:3
x11-libs/libX11
virtual/freedesktop-icon-theme
ayatana? ( dev-libs/libappindicator:3 )
crypt? ( dev-libs/libgcrypt:0= )
freerdp? ( ~net-misc/freerdp-2.0.0_pre20160722 )
gnome-keyring? ( app-crypt/libsecret )
spice? ( net-misc/spice-gtk[gtk3] )
ssh? ( net-libs/libssh[sftp]
x11-libs/vte:2.91 )
telepathy? ( net-libs/telepathy-glib )
webkit? ( net-libs/webkit-gtk:4 )
zeroconf? ( net-dns/avahi[gtk3] )
"
DEPEND="${RDEPEND}
dev-util/intltool
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
DOCS=( README.md )
S="${WORKDIR}/Remmina-${MY_PV}"
src_configure() {
local mycmakeargs=(
-DWITH_APPINDICATOR=$(usex ayatana)
-DWITH_GCRYPT=$(usex crypt)
-DWITH_FREERDP=$(usex freerdp)
-DWITH_LIBSECRET=$(usex gnome-keyring)
-DWITH_GETTEXT=$(usex nls)
-DWITH_TRANSLATIONS=$(usex nls)
-DWITH_SPICE=$(usex spice)
-DWITH_LIBSSH=$(usex ssh)
-DWITH_VTE=$(usex ssh)
-DWITH_TELEPATHY=$(usex telepathy)
-DWITH_SURVEY=$(usex webkit)
-DWITH_AVAHI=$(usex zeroconf)
-DGTK_VERSION=3
)
cmake-utils_src_configure
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
gnome2_icon_cache_update
elog "To get additional features, some optional runtime dependencies"
elog "may be installed:"
elog ""
optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
optfeature "XDMCP support" x11-base/xorg-server[xephyr]
}
pkg_postrm() {
gnome2_icon_cache_update
}
|
GitWeb