blob: 5b4f8fd020ad378501fe88f6a08e166f77306200 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
VALA_MIN_API_VERSION="0.14"
VALA_USE_DEPEND="vapigen"
inherit desktop eutils meson readme.gentoo-r1 vala xdg-utils
DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI"
HOMEPAGE="https://www.spice-space.org https://cgit.freedesktop.org/spice/spice-gtk/"
LICENSE="LGPL-2.1"
SLOT="0"
SRC_URI="https://www.spice-space.org/download/gtk/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="+gtk3 +introspection lz4 mjpeg policykit pulseaudio sasl smartcard usbredir vala webdav libressl"
# TODO:
# * check if sys-freebsd/freebsd-lib (from virtual/acl) provides acl/libacl.h
# * use external pnp.ids as soon as that means not pulling in gnome-desktop
RDEPEND="
>=dev-libs/glib-2.46:2
dev-libs/json-glib:0=
media-libs/gst-plugins-base:1.0
media-libs/gst-plugins-good:1.0
media-libs/gstreamer:1.0[introspection?]
media-libs/opus
sys-libs/zlib
virtual/jpeg:0=
>=x11-libs/cairo-1.2
>=x11-libs/pixman-0.17.7
gtk3? ( x11-libs/gtk+:3[introspection?] )
introspection? ( dev-libs/gobject-introspection )
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
lz4? ( app-arch/lz4 )
pulseaudio? (
media-plugins/gst-plugins-pulse:1.0
)
sasl? ( dev-libs/cyrus-sasl )
smartcard? ( app-emulation/qemu[smartcard] )
usbredir? (
sys-apps/hwids
>=sys-apps/usbredir-0.4.2
virtual/libusb:1
policykit? (
sys-apps/acl
>=sys-auth/polkit-0.110-r1
!~sys-auth/polkit-0.111 )
)
webdav? (
net-libs/phodav:2.0
>=net-libs/libsoup-2.49.91 )
"
# TODO: spice-gtk has an automagic dependency on x11-libs/libva without a
# configure knob. The package is relatively lightweight so we just depend
# on it unconditionally for now. It would be cleaner to transform this into
# a USE="vaapi" conditional and patch the buildsystem...
RDEPEND="${RDEPEND}
amd64? ( x11-libs/libva:= )
arm64? ( x11-libs/libva:= )
x86? ( x11-libs/libva:= )
"
DEPEND="${RDEPEND}
>=app-emulation/spice-protocol-0.14.1
dev-perl/Text-CSV
dev-util/glib-utils
>=dev-util/gtk-doc-am-1.14
>=dev-util/intltool-0.40.0
>=sys-devel/gettext-0.17
virtual/pkgconfig
vala? ( $(vala_depend) )
"
src_prepare() {
# bug 558558
export GIT_CEILING_DIRECTORIES="${WORKDIR}"
default
use vala && vala_src_prepare
}
src_configure() {
# Prevent sandbox violations, bug #581836
# https://bugzilla.gnome.org/show_bug.cgi?id=744134
# https://bugzilla.gnome.org/show_bug.cgi?id=744135
addpredict /dev
# Clean up environment, bug #586642
xdg_environment_reset
local emesonargs=(
$(meson_feature gtk3 gtk)
$(meson_feature introspection)
$(meson_use mjpeg builtin-mjpeg)
$(meson_feature policykit polkit)
$(meson_feature pulseaudio pulse)
$(meson_feature sasl)
$(meson_feature smartcard)
$(meson_feature usbredir)
$(usex usbredir -Dusb-acl-helper-dir=/usr/libexec)
$(usex usbredir -Dusb-ids-path=/usr/share/misc/usb.ids)
$(meson_feature vala vapi)
$(meson_feature webdav)
)
meson_src_configure
}
src_compile() {
# Prevent sandbox violations, bug #581836
# https://bugzilla.gnome.org/show_bug.cgi?id=744134
# https://bugzilla.gnome.org/show_bug.cgi?id=744135
addpredict /dev
meson_src_compile
}
src_install() {
meson_src_install
make_desktop_entry spicy Spicy "utilities-terminal" "Network;RemoteAccess;"
readme.gentoo_create_doc
}
|
GitWeb