blob: 15fd9ad97135a03611984a68ff42c055d5845005 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit bash-completion-r1 distutils-r1 optfeature
DESCRIPTION="youtube-dl fork with additional features and fixes"
HOMEPAGE="https://github.com/yt-dlp/yt-dlp"
SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
LICENSE="Unlicense"
SLOT="0"
KEYWORDS="amd64 arm ~arm64 ~hppa ppc ppc64 ~riscv x86 ~x64-macos"
RDEPEND="
dev-python/pycryptodome[${PYTHON_USEDEP}]
!net-misc/youtube-dl[-yt-dlp(-)]"
distutils_enable_tests pytest
python_prepare_all() {
distutils-r1_python_prepare_all
# adjust requires for pycryptodome and optional dependencies (bug #828466)
sed -ri requirements.txt \
-e "s/^(pycryptodome)x/\1/" \
-e "/^(brotli.*|mutagen|websockets)/d" || die
}
python_test() {
epytest -m 'not download' -p no:markdown
}
python_install_all() {
dodoc README.md Changelog.md supportedsites.md
doman yt-dlp.1
dobashcomp completions/bash/yt-dlp
insinto /usr/share/fish/vendor_completions.d
doins completions/fish/yt-dlp.fish
insinto /usr/share/zsh/site-functions
doins completions/zsh/_yt-dlp
rm -r "${ED}"/usr/share/doc/yt_dlp || die
newbin - youtube-dl <<-EOF
#!/usr/bin/env sh
exec yt-dlp --compat-options youtube-dl "\${@}"
EOF
}
pkg_postinst() {
optfeature "various features (merging tracks, streamed content)" media-video/ffmpeg
has_version media-video/atomicparsley || # allow fallback but don't advertise
optfeature "embedding metadata thumbnails in MP4/M4A files" media-libs/mutagen
if [[ ! ${REPLACING_VERSIONS} ]]; then
elog 'A wrapper using "yt-dlp --compat-options youtube-dl" was installed'
elog 'as "youtube-dl". This is strictly for compatibility and it is'
elog 'recommended to use "yt-dlp" directly, it may be removed in the future.'
fi
}
|
GitWeb
