sci-biology/infernal/infernal-1.0.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

DESCRIPTION="Inference of RNA alignments"
HOMEPAGE="http://infernal.janelia.org/"
SRC_URI="ftp://selab.janelia.org/pub/software/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
IUSE="mpi"
KEYWORDS="amd64 x86"

RDEPEND="mpi? ( virtual/mpi )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${P}-parallel-build.patch
	"${FILESDIR}"/${P}-overflows.patch
	"${FILESDIR}"/${P}-perl-5.16-2.patch
	"${FILESDIR}"/${P}-ldflags.patch
	"${FILESDIR}"/${P}-respect-DESTDIR.patch
)

src_configure() {
	econf $(use_enable mpi)
}

src_install() {
	DOCS=( 00README* Userguide.pdf documentation/release-notes )
	default

	pushd documentation/manpages >/dev/null || die
	local i
	for i in *.man; do
		newman "${i}" "${i/.man/.1}"
	done
	popd >/dev/null || die

	insinto /usr/share/${PN}
	doins -r benchmarks tutorial intro matrices
}