sci-geosciences/xtide/xtide-2.13.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

inherit autotools eutils gnome2-utils

DESCRIPTION="XTide provides tide and current predictions in a wide variety of formats"
HOMEPAGE="http://www.flaterco.com/xtide/"
SRC_URI="ftp://ftp.flaterco.com/xtide/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gps"

DEPEND="
	media-libs/libpng:0
	>=sci-geosciences/libtcd-2.2.5_p2
	x11-libs/libX11
	x11-libs/libXaw3d
	x11-libs/libXpm
	x11-libs/libXt
	gps? ( sci-geosciences/gpsd )"
RDEPEND="${DEPEND}
	media-fonts/font-schumacher-misc"
DEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-{Werror,gps-switch}.patch
	eautoreconf
}

src_configure() {
	econf \
		$(use_with gps)
}

src_install() {
	dobin xtide tide xttpd
	doman *.[18]

	echo 'HFILE_PATH=/usr/share/harmonics' > 50xtide_harm
	doenvd 50xtide_harm

	newicon -s 48 iconsrc/icon_48x48_orig.png ${PN}.png

	make_desktop_entry ${PN} 'Tide prediction' ${PN} 'Science'
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}