blob: 9ea245581686bbbc1261e1aa139953c3acb2a771 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8,9} )
inherit autotools linux-info python-any-r1
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
DESCRIPTION="Linux application sandboxing and distribution framework"
HOMEPAGE="https://flatpak.org/"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc gtk kde introspection policykit seccomp systemd"
RDEPEND="
acct-group/flatpak
acct-user/flatpak
>=app-arch/libarchive-2.8
app-arch/zstd
>=app-crypt/gpgme-1.1.8
>=dev-libs/appstream-glib-0.5.10
>=dev-libs/glib-2.56:2
>=dev-libs/libxml2-2.4
dev-libs/json-glib
>=dev-util/ostree-2019.5[gpg(+)]
|| (
dev-util/ostree[curl]
dev-util/ostree[soup]
)
>=gnome-base/dconf-0.26
>=net-libs/libsoup-2.4
sys-apps/bubblewrap
sys-apps/dbus
>=sys-fs/fuse-2.9.9:0
sys-apps/xdg-dbus-proxy
x11-apps/xauth
x11-libs/gdk-pixbuf:2
x11-libs/libXau
policykit? ( >=sys-auth/polkit-0.98 )
seccomp? ( sys-libs/libseccomp )
systemd? ( sys-apps/systemd )
"
DEPEND="${RDEPEND}"
BDEPEND="
>=sys-devel/automake-1.13.4
>=sys-devel/gettext-0.18.2
virtual/pkgconfig
dev-util/gdbus-codegen
sys-devel/bison
introspection? ( >=dev-libs/gobject-introspection-1.40 )
doc? (
>=dev-util/gtk-doc-1.20
dev-libs/libxslt
)
$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
"
PDEPEND="
gtk? ( sys-apps/xdg-desktop-portal-gtk )
kde? ( kde-plasma/xdg-desktop-portal-kde )
"
python_check_deps() {
has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
}
pkg_setup() {
local CONFIG_CHECK="~USER_NS"
linux-info_pkg_setup
python-any-r1_pkg_setup
}
src_configure() {
local myeconfargs=(
--enable-sandboxed-triggers
--enable-xauth
--localstatedir="${EPREFIX}"/var
--with-system-bubblewrap
--with-system-dbus-proxy
$(use_enable doc documentation)
$(use_enable doc gtk-doc)
$(use_enable introspection)
$(use_enable policykit system-helper)
$(use_enable seccomp)
$(use_with systemd)
)
econf "${myeconfargs[@]}"
}
|
GitWeb