blob: b01dab04c1a17813f57171e294d78f4cb61ec0d0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
# (needed due to CMAKE_BUILD_TYPE != Gentoo)
CMAKE_MIN_VERSION=3.7.0-r1
PYTHON_COMPAT=( python2_7 )
inherit cmake-utils git-r3 llvm python-any-r1
DESCRIPTION="The LLVM linker (link editor)"
HOMEPAGE="https://llvm.org/"
SRC_URI=""
EGIT_REPO_URI="https://git.llvm.org/git/lld.git
https://github.com/llvm-mirror/lld.git"
LICENSE="UoI-NCSA"
SLOT="0"
KEYWORDS=""
IUSE="test"
RDEPEND="~sys-devel/llvm-${PV}"
DEPEND="${RDEPEND}
test? ( $(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]") )"
# least intrusive of all
CMAKE_BUILD_TYPE=RelWithDebInfo
python_check_deps() {
has_version "dev-python/lit[${PYTHON_USEDEP}]"
}
pkg_setup() {
llvm_pkg_setup
use test && python-any-r1_pkg_setup
}
src_unpack() {
if use test; then
# needed for patched gtest
git-r3_fetch "https://git.llvm.org/git/llvm.git
https://github.com/llvm-mirror/llvm.git"
fi
git-r3_fetch
if use test; then
git-r3_checkout https://llvm.org/git/llvm.git \
"${WORKDIR}"/llvm '' utils/{lit,unittest}
fi
git-r3_checkout
}
src_configure() {
local mycmakeargs=(
-DBUILD_SHARED_LIBS=ON
-DLLVM_INCLUDE_TESTS=$(usex test)
)
use test && mycmakeargs+=(
-DLLVM_BUILD_TESTS=ON
-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
-DLLVM_LIT_ARGS="-vv"
)
cmake-utils_src_configure
}
src_test() {
cmake-utils_src_make check-lld
}
|
GitWeb
