blob: cc187009eb9760830511ea90f33d30808b9e3165 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Copyright 2020-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit kernel-install toolchain-funcs
MY_P=linux-${PV%.*}
GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
BINPKG=${P/-bin/}-1
DESCRIPTION="Pre-built Linux kernel with Gentoo patches"
HOMEPAGE="https://www.kernel.org/"
SRC_URI+="
https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
amd64? (
https://dev.gentoo.org/~sam/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
-> ${BINPKG}.amd64.xpak
)
arm64? (
https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
-> ${BINPKG}.arm64.xpak
)
ppc64? (
https://dev.gentoo.org/~sam/binpkg/ppc64le/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
-> ${BINPKG}.ppc64le.xpak
)
x86? (
https://dev.gentoo.org/~sam/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
-> ${BINPKG}.x86.xpak
)
"
S=${WORKDIR}
LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
RDEPEND="
!sys-kernel/gentoo-kernel:${SLOT}
"
PDEPEND="
>=virtual/dist-kernel-${PV}
"
BDEPEND="
sys-devel/bc
sys-devel/flex
virtual/libelf
virtual/yacc
"
QA_PREBUILT='*'
KV_LOCALVERSION='-gentoo-dist'
KPV=${PV}${KV_LOCALVERSION}
src_unpack() {
default
# ARCH=ppc64, but tarball is ppc64le. Update if we ever introduce ppc64be binpkg.
ebegin "Unpacking ${BINPKG}.${ARCH/%ppc64/ppc64le}.xpak"
tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH/%ppc64/ppc64le}.xpak")
eend ${?} || die "Unpacking ${BINPKG} failed"
}
src_prepare() {
local PATCHES=(
# meh, genpatches have no directory
"${WORKDIR}"/*.patch
)
cd "${MY_P}" || die
default
}
src_configure() {
# force ld.bfd if we can find it easily
local LD="$(tc-getLD)"
if type -P "${LD}.bfd" &>/dev/null; then
LD+=.bfd
fi
tc-export_build_env
local makeargs=(
V=1
HOSTCC="$(tc-getBUILD_CC)"
HOSTCXX="$(tc-getBUILD_CXX)"
HOSTCFLAGS="${BUILD_CFLAGS}"
HOSTLDFLAGS="${BUILD_LDFLAGS}"
CROSS_COMPILE=${CHOST}-
AS="$(tc-getAS)"
CC="$(tc-getCC)"
LD="${LD}"
AR="$(tc-getAR)"
NM="$(tc-getNM)"
STRIP=":"
OBJCOPY="$(tc-getOBJCOPY)"
OBJDUMP="$(tc-getOBJDUMP)"
# we need to pass it to override colliding Gentoo envvar
ARCH="$(tc-arch-kernel)"
O="${WORKDIR}"/modprep
)
mkdir modprep || die
cp "usr/src/linux-${KPV}/.config" modprep/ || die
emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
}
src_test() {
kernel-install_test "${KPV}" \
"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
"lib/modules/${KPV}"
}
src_install() {
mv lib usr "${ED}"/ || die
# FIXME: requires proper mount-boot
if [[ -d boot/dtbs ]]; then
mv boot "${ED}"/ || die
fi
# strip out-of-source build stuffs from modprep
# and then copy built files
find modprep -type f '(' \
-name Makefile -o \
-name '*.[ao]' -o \
'(' -name '.*' -a -not -name '.config' ')' \
')' -delete || die
rm modprep/source || die
cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
}
|
GitWeb