sys-power/sispmctl/sispmctl-4.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit systemd udev

DESCRIPTION="GEMBIRD SiS-PM control utility"
HOMEPAGE="http://sispmctl.sourceforge.net/"
SRC_URI="mirror://sourceforge/sispmctl/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="static-libs"

DEPEND="
	virtual/libusb:0
"
RDEPEND="
	${DEPEND}
	acct-group/sispmctl
"

DOCS="AUTHORS README ChangeLog"

src_configure() {
	local myeconfargs=(
		$(use_enable static-libs static)
		--enable-webless
	)

	econf "${myeconfargs[@]}"
}

src_install() {
	default

	find "${ED}" -name '*.la' -delete || die

	## install udev rules which make the device files writable
	## by the members of the group sispmctl
	udev_dorules examples/60-sispmctl.rules

	systemd_dounit examples/${PN}.service

	einfo "Add users who may run ${PN} to the group '${PN}'"
}