blob: e1b85646fdb2ea8629fb714e6dbf001f3a108c0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit git-r3 meson python-any-r1 virtualx xdg
DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
HOMEPAGE="https://github.com/yshui/picom"
EGIT_REPO_URI="https://github.com/yshui/picom.git"
LICENSE="MPL-2.0 MIT"
SLOT="0"
IUSE="+config-file dbus +doc +drm opengl pcre test"
REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
RESTRICT="test" # but tests require dbus_next
RDEPEND="dev-libs/libev
dev-libs/uthash
x11-libs/libX11
x11-libs/libxcb
x11-libs/libXext
x11-libs/pixman
x11-libs/xcb-util-image
x11-libs/xcb-util-renderutil
config-file? (
dev-libs/libconfig:=
)
dbus? ( sys-apps/dbus )
drm? ( x11-libs/libdrm )
opengl? ( virtual/opengl )
pcre? ( dev-libs/libpcre2:= )
!x11-misc/compton"
DEPEND="${RDEPEND}
x11-base/xorg-proto"
BDEPEND="virtual/pkgconfig
doc? ( app-text/asciidoc )
test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
"
DOCS=( README.md picom.sample.conf )
python_check_deps() {
python_has_version "dev-python/xcffib[${PYTHON_USEDEP}]"
}
pkg_setup() {
use test && python-any-r1_pkg_setup
}
src_configure() {
local emesonargs=(
$(meson_use config-file config_file)
$(meson_use dbus)
$(meson_use doc with_docs)
$(meson_use opengl)
$(meson_use pcre regex)
)
meson_src_configure
}
src_test() {
virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
}
|
GitWeb
