blob: 3659998ac4a4adf4c69392b64f026c0c03b1a6af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
GNOME2_LA_PUNT="yes"
GNOME2_EAUTORECONF="yes"
PYTHON_COMPAT=( python{2_7,3_6,3_7,3_8,3_9} )
VALA_USE_DEPEND="vapigen"
inherit db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python-single-r1 vala
DESCRIPTION="GNOME database access library"
HOMEPAGE="https://www.gnome-db.org/"
LICENSE="GPL-2+ LGPL-2+"
IUSE="berkdb canvas debug firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres reports sourceview ssl vala"
REQUIRED_USE="
reports? ( ${PYTHON_REQUIRED_USE} )
canvas? ( gtk )
graphviz? ( gtk )
sourceview? ( gtk )
vala? ( introspection )
"
# firebird license is not GPL compatible
SLOT="5/4" # subslot = libgda-5.0 soname version
KEYWORDS="~amd64 ~ppc64 ~x86"
RDEPEND="
app-text/iso-codes
>=dev-libs/glib-2.32:2
>=dev-libs/libxml2-2
dev-libs/libxslt
sys-libs/readline:0=
sys-libs/ncurses:0=
berkdb? ( sys-libs/db:* )
firebird? ( dev-db/firebird )
gnome-keyring? ( app-crypt/libsecret )
gtk? (
>=x11-libs/gtk+-3.0.0:3
canvas? ( x11-libs/goocanvas:2.0= )
sourceview? ( x11-libs/gtksourceview:3.0 )
graphviz? ( media-gfx/graphviz )
)
http? ( >=net-libs/libsoup-2.24:2.4 )
introspection? ( >=dev-libs/gobject-introspection-1.30:= )
json? ( dev-libs/json-glib )
ldap? ( net-nds/openldap:= )
mdb? ( >app-office/mdbtools-0.5:= )
mysql? ( dev-db/mysql-connector-c:0= )
postgres? ( dev-db/postgresql:= )
reports? (
${PYTHON_DEPS}
dev-java/fop
dev-python/reportlab )
ssl? ( dev-libs/openssl:0= )
>=dev-db/sqlite-3.10.2:3=
vala? ( dev-libs/libgee:0.8 )
"
# java dep shouldn't rely on slots, bug #450004
# TODO: libgee shouldn't be needed at build with USE=-vala, but needs build system fixes - bug 674066
DEPEND="${RDEPEND}
dev-libs/libgee:0.8
>=app-text/gnome-doc-utils-0.9
app-text/yelp-tools
dev-util/glib-utils
dev-util/gtk-doc-am
>=dev-util/intltool-0.40.6
virtual/pkgconfig
java? ( >=virtual/jdk-1.6 )
vala? ( $(vala_depend) )
"
# FIXME: lots of tests failing. Check if they still fail in 5.1.2
# firebird support bindist-restricted because it is not GPL compatible
RESTRICT="
test
firebird? ( bindist )
"
pkg_setup() {
java-pkg-opt-2_pkg_setup
use reports && python-single-r1_pkg_setup
}
src_prepare() {
# Fix compilation with -Werror=format-security (from 'master')
eapply "${FILESDIR}"/${PN}-5.2.4-format-security.patch
use berkdb && append-cppflags "-I$(db_includedir)"
use reports ||
sed -e '/SUBDIRS =/ s/trml2html//' \
-e '/SUBDIRS =/ s/trml2pdf//' \
-i libgda-report/RML/Makefile.{am,in} || die
# Prevent file collisions with libgda:4
eapply "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
eapply "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
# Move files with mv (since epatch can't handle rename diffs) and
# update pre-generated gtk-doc files (for non-git versions of libgda)
local f
for f in tools/browser/doc/gda-browser* ; do
mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
done
for f in tools/browser/doc/html/gda-browser.devhelp* ; do
sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
-i ${f} || die "sed ${f} failed"
mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
done
for f in control-center/data/*_gda-control-center.png ; do
mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
die "mv ${f} failed"
done
gnome2_src_prepare
java-pkg-opt-2_src_prepare
use vala && vala_src_prepare
# Support JRE 1.8 (from Fedora) - patches configure, so applied AFTER gnome2_src_prepare runs eautoreconf
eapply "${FILESDIR}"/${PN}-5.2.4-jre18.patch
# my_bool patch: https://bugs.gentoo.org/692672
eapply "${FILESDIR}"/${PN}-5.2.8-my_bool-error.patch
}
src_configure() {
# Upstream broken configure handling for UI library introspection and vala bindings if passing a choice with use_enable - https://gitlab.gnome.org/GNOME/libgda/issues/158
# But if we don't pass an explicit choice, it behaves as we need (only enable them if --enable-ui AND the appropriate --enable-introspection or --enable-vala)
gnome2_src_configure \
--with-help \
--disable-default-binary \
--disable-static \
--enable-system-sqlite \
$(use_with berkdb bdb /usr) \
$(use_with canvas goocanvas) \
$(use_enable debug) \
$(use_with firebird firebird /usr) \
$(use_with gnome-keyring libsecret) \
$(use_with graphviz) \
$(use_with gtk ui) \
$(use_with http libsoup) \
$(use_enable introspection) \
"$(use_with java java $JAVA_HOME)" \
$(use_enable json) \
$(use_with ldap) \
--with-ldap-libdir-name="$(get_libdir)" \
$(use_with mdb mdb /usr) \
$(use_with mysql mysql /usr) \
$(use_with oci8 oracle) \
$(use_with postgres postgres /usr) \
$(use_enable ssl crypto) \
$(use_with sourceview gtksourceview) \
$(use_enable vala)
}
pkg_preinst() {
gnome2_pkg_preinst
java-pkg-opt-2_pkg_preinst
}
src_install() {
gnome2_src_install
if use reports; then
for t in trml2{html,pdf}; do
python_scriptinto /usr/share/libgda-5.0/gda_${t}
python_doscript libgda-report/RML/${t}/${t}.py
done
fi
}
|