blob: 8a2969ec001eed442ce45f533bc1eddb2e8ec706 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit python-single-r1 cmake
DESCRIPTION="Open source multimedia framework for television broadcasting"
HOMEPAGE="https://www.mltframework.org/"
SRC_URI="https://github.com/mltframework/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0/7"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
IUSE="debug ffmpeg frei0r glaxnimate gtk jack libsamplerate opencv opengl python qt5 qt6 rtaudio rubberband sdl sox test vdpau vidstab xine xml"
REQUIRED_USE="
?? ( qt5 qt6 )
glaxnimate? ( || ( qt5 qt6 ) )
python? ( ${PYTHON_REQUIRED_USE} )
"
# Needs unpackaged 'kwalify'
RESTRICT="test"
# rtaudio will use OSS on non linux OSes
# Qt already needs FFTW/PLUS so let's just always have it on to ensure
# MLT is useful: bug #603168.
DEPEND="
>=media-libs/libebur128-1.2.2:=
sci-libs/fftw:3.0=
ffmpeg? ( media-video/ffmpeg:0=[vdpau?] )
frei0r? ( media-plugins/frei0r-plugins )
gtk? (
media-libs/libexif
x11-libs/pango
)
jack? (
>=dev-libs/libxml2-2.5
media-libs/ladspa-sdk
virtual/jack
)
libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
opencv? ( >=media-libs/opencv-4.5.1:=[contrib] )
opengl? (
media-libs/libglvnd
media-video/movit
)
python? ( ${PYTHON_DEPS} )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
media-libs/libexif
x11-libs/libX11
)
qt6? (
dev-qt/qt5compat:6
dev-qt/qtbase:6[gui,widgets,xml]
dev-qt/qtsvg:6
media-libs/libexif
x11-libs/libX11
)
rtaudio? (
>=media-libs/rtaudio-4.1.2
kernel_linux? ( media-libs/alsa-lib )
)
rubberband? ( media-libs/rubberband )
sdl? (
media-libs/libsdl2[X,opengl,video]
media-libs/sdl2-image
)
sox? ( media-sound/sox )
vidstab? ( media-libs/vidstab )
xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
xml? ( >=dev-libs/libxml2-2.5 )
"
# java? ( >=virtual/jre-1.8:* )
# perl? ( dev-lang/perl )
# php? ( dev-lang/php )
# ruby? ( ${RUBY_DEPS} )
# sox? ( media-sound/sox )
# tcl? ( dev-lang/tcl:0= )
RDEPEND="${DEPEND}"
BDEPEND="
virtual/pkgconfig
python? ( >=dev-lang/swig-2.0 )
"
DOCS=( AUTHORS NEWS README.md )
PATCHES=(
"${FILESDIR}"/${PN}-6.10.0-swig-underlinking.patch
"${FILESDIR}"/${PN}-6.22.1-no_lua_bdepend.patch
"${FILESDIR}"/${PN}-7.0.1-cmake-symlink.patch
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
# Respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
if use python; then
sed -i "/mlt.so/s/ -lmlt++ /& ${CFLAGS} ${LDFLAGS} /" src/swig/python/build || die
python_fix_shebang src/swig/python
fi
cmake_src_prepare
}
src_configure() {
local mycmakeargs=(
-DCMAKE_SKIP_RPATH=ON
-DGPL=ON
-DGPL3=ON
-DBUILD_TESTING=$(usex test)
-DCLANG_FORMAT=OFF
-DMOD_KDENLIVE=ON
-DMOD_SDL1=OFF
-DMOD_SDL2=$(usex sdl)
-DMOD_AVFORMAT=$(usex ffmpeg)
-DMOD_PLUS=ON
-DMOD_FREI0R=$(usex frei0r)
-DMOD_GDK=$(usex gtk)
-DMOD_JACKRACK=$(usex jack)
-DMOD_GLAXNIMATE=$(usex glaxnimate $(usex qt5) OFF)
-DMOD_GLAXNIMATE_QT6=$(usex glaxnimate $(usex qt6) OFF)
-DMOD_RESAMPLE=$(usex libsamplerate)
-DMOD_OPENCV=$(usex opencv)
-DMOD_MOVIT=$(usex opengl)
-DMOD_QT=$(usex qt5)
-DMOD_QT6=$(usex qt6)
-DMOD_RTAUDIO=$(usex rtaudio)
-DMOD_RUBBERBAND=$(usex rubberband)
-DMOD_VIDSTAB=$(usex vidstab)
-DMOD_XINE=$(usex xine)
-DMOD_XML=$(usex xml)
-DMOD_SOX=$(usex sox)
)
# TODO: rework upstream CMake to allow controlling MMX/SSE/SSE2
# TODO: add swig language bindings?
# see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
if use python; then
mycmakeargs+=( -DSWIG_PYTHON=ON )
fi
cmake_src_configure
}
src_install() {
cmake_src_install
insinto /usr/share/${PN}
doins -r demo
#
# Install SWIG bindings
#
docinto swig
if use python; then
dodoc "${S}"/src/swig/python/play.py
python_optimize
fi
}
|