Add dev-vcs/subversion-1.7.18

2 files changed, 500 insertions, 0 deletions

diff --git a/dev-vcs/subversion/Manifest b/dev-vcs/subversion/Manifest
index 1db3910e..57c9c792 100644
--- a/dev-vcs/subversion/Manifest
+++ b/dev-vcs/subversion/Manifest
@@ -8,5 +8,7 @@ AUX svnserve.initd2 828 SHA256 8f123253c3bfb9bbe87210a9e1facc7f52df371747dbc1883
 AUX svnserve.xinetd 332 SHA256 267f30c78ef6428aeeb97d3c64c06b9acfba4bc624766fc3c6a6d2c4133799a2 SHA512 80b486507d03f430e189ef65901ed185f487651400bada5709f544954eb6175d20a11cf98893f80ec963e434c5db5642bf9d1603d698ad8bbf96b88fa45ddbae WHIRLPOOL 0c5ed79630859706f18b56fbb910b4b2dc6b480cdf72a929f7d33232f23ee1eb7110b98c4a8e06cd06c620b9f4ff081bfae23edd1f6a65fade2ac5081dbf3962
 DIST subversion-1.7.14.tar.bz2 6045932 SHA256 c4ac8f37eb0ebd38901bfa6f1c7e4d7716d32d7460ee0cee520381ca2f5b120d SHA512 cc7df3a2d258cda65a3fefc1fb9bcc91f78ec817c8d32e561eae7cf59de3d1d5c843594150b63c60c724e4b3df88da319763f814f418d106461adcc78b323840 WHIRLPOOL 21d879775ed0bed15d17b83070eb26269f8d3cc0420be54e0d326b7b6f410b9fee11d2f8d2926f930c66c66a47a6396275ddf20120436b978c0a318bb963f0e0
 DIST subversion-1.7.17.tar.bz2 6008028 SHA256 2a66e4c5d2a8a919914a2e75f76467ef5457d0f96efc1e1c080fa02675867be3 SHA512 60760d9c2d01dcb664b545611e5ac5bb400154568eb811392c7903b223296d8f4e52d5154cfcb5b2e91d39de262c2ad958385190b87458f387fb38e5f3d2eaea WHIRLPOOL 20604f31589aa2fa2eff1869d7af7e80c4cf4fccd40c9d9bd1af8d1628171a381452796d38bc86ccafbf38232a6194d747b6c271f49064f2a361101edb73de00
+DIST subversion-1.7.18.tar.bz2 6096031 SHA256 f67381ce62b69bdb373e4c38ff84576677316904753536a78630603cacc5d91a SHA512 7a73b262701f7df6bc61acec4a38e8f6a04ff923a4b21669dba62d5357eb6ebce9e47d044d246ed9889eeefc6413569b5e4ee0f53cc9e78f8d24edb30e47f1a3 WHIRLPOOL b5bc15b8ae805659abbbc3f00f052f0b25f030a05a2ca5a60ee5e884b8dac6ff800a8c8d73b374c5c4f64df0fe17628a43f81e10047134a2ffef241c9a5ee90f
 EBUILD subversion-1.7.14.ebuild 15201 SHA256 a302a8380fcc33410cb64b77aecabf21eb18ddfaec5e6f314d8587a1091a2bbe SHA512 aa1c6d636ee33818aa0d42deabae0ee9960b890a0919af4c8324760cf36704427ad37b942642a2f8bda42e241674983b3e7b4e11dd6215eead7695a463b4885f WHIRLPOOL b3b403bba6cfd8fb0bdad18b077baf78357808ef20f17cf23e02fb4969f9dd10a4e263a246cfc15e5257418c91f889d6bd2c253f24cbe18d0d53ff464f9378dd
 EBUILD subversion-1.7.17.ebuild 15227 SHA256 fc09b00c5d5b821a5668d5fefd3f13903a3ce9b86a538dcadd05e30d242fad8c SHA512 0872044772d28e5ed62c73e38974439803b7b742a3b41c0a24a192e2ae89af902653112d2d32e30ce38983fdd4d9fecaf2615013928e6806c7c2d31d11260372 WHIRLPOOL fe16e5aff07e51a62280160b6e2ff68fa3e10edf7385b62aee0f67c815f1ec97ac198bb19d8e6edfcb7752d68cddf55b18588a9ed7107676defcc3c16dfa540a
+EBUILD subversion-1.7.18.ebuild 15238 SHA256 d0b22ed4baf084276c52a0755df373468e7bcd9a2b0fbc8a26fb83284ac8ebb7 SHA512 0b25b25641c840093dff16a06afa3468a5a5fb4351250547f39a0c61bf3b269bd04c9c86539427ff4945fc7ab16eff0474e35e15108e98e177a7a416f4c5581b WHIRLPOOL 497f55fc9936e29ad7f11be5ef9d64d4d3932b3249b6dd62381b271444bd806c9d975ca1ea7f071cadd0b3bcf069b83700a4bac1db226efc3b6ade56aeaa2301
diff --git a/dev-vcs/subversion/subversion-1.7.18.ebuild b/dev-vcs/subversion/subversion-1.7.18.ebuild
new file mode 100644
index 00000000..659ad40e
--- /dev/null
+++ b/dev-vcs/subversion/subversion-1.7.18.ebuild
@@ -0,0 +1,498 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/subversion/subversion-1.7.18.ebuild,v 1.1 2014/08/14 16:54:14 tommy Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+DISTUTILS_OPTIONAL=1
+WANT_AUTOMAKE="none"
+MY_P="${P/_/-}"
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools bash-completion-r1 db-use depend.apache distutils-r1 elisp-common flag-o-matic java-pkg-opt-2 libtool multilib perl-module eutils toolchain-funcs
+
+DESCRIPTION="Advanced version control system"
+HOMEPAGE="http://subversion.apache.org/"
+SRC_URI="mirror://apache/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Subversion GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="apache2 berkdb clang ctypes-python debug doc +dso extras gnome-keyring java kde nls perl python ruby sasl test vim-syntax +webdav-neon webdav-serf"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.6.18[threadsafe(+)]
+	>=dev-libs/apr-1.3:1
+	>=dev-libs/apr-util-1.3:1
+	dev-libs/expat
+	sys-libs/zlib
+	berkdb? ( >=sys-libs/db-4.0.14 )
+	ctypes-python? ( ${PYTHON_DEPS} )
+	gnome-keyring? ( dev-libs/glib:2 sys-apps/dbus gnome-base/gnome-keyring )
+	kde? ( sys-apps/dbus dev-qt/qtcore:4 dev-qt/qtdbus:4 dev-qt/qtgui:4 >=kde-base/kdelibs-4:4 )
+	perl? ( dev-lang/perl )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( >=dev-lang/ruby-1.8.2:1.8
+		dev-ruby/rubygems[ruby_targets_ruby18] )
+	sasl? ( dev-libs/cyrus-sasl )
+	webdav-neon? ( >=net-libs/neon-0.28 )
+	webdav-serf? ( >=net-libs/serf-0.3.0 )"
+RDEPEND="${COMMON_DEPEND}
+	apache2? ( www-servers/apache[apache2_modules_dav] )
+	java? ( >=virtual/jre-1.5 )
+	kde? ( kde-base/kwalletd )
+	nls? ( virtual/libintl )
+	perl? ( dev-perl/URI )"
+# Note: ctypesgen doesn't need PYTHON_USEDEP, it's used once
+DEPEND="${COMMON_DEPEND}
+	test? ( ${PYTHON_DEPS} )
+	!!<sys-apps/sandbox-1.6
+	ctypes-python? ( dev-python/ctypesgen )
+	doc? ( app-doc/doxygen )
+	gnome-keyring? ( virtual/pkgconfig )
+	java? ( >=virtual/jdk-1.5 )
+	kde? ( virtual/pkgconfig )
+	nls? ( sys-devel/gettext )
+	webdav-neon? ( virtual/pkgconfig )"
+
+REQUIRED_USE="
+	ctypes-python? ( ${PYTHON_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( ${PYTHON_REQUIRED_USE} )"
+
+want_apache
+
+pkg_setup() {
+	if use berkdb; then
+		local apu_bdb_version="$(${EPREFIX}/usr/bin/apu-1-config --includes \
+			| grep -Eoe '-I${EPREFIX}/usr/include/db[[:digit:]]\.[[:digit:]]' \
+			| sed 's:.*b::')"
+		einfo
+		if [[ -z "${SVN_BDB_VERSION}" ]]; then
+			if [[ -n "${apu_bdb_version}" ]]; then
+				SVN_BDB_VERSION="${apu_bdb_version}"
+				einfo "Matching db version to apr-util"
+			else
+				SVN_BDB_VERSION="$(db_ver_to_slot "$(db_findver sys-libs/db 2>/dev/null)")"
+				einfo "SVN_BDB_VERSION variable isn't set. You can set it to enforce using of specific version of Berkeley DB."
+			fi
+		fi
+		einfo "Using: Berkeley DB ${SVN_BDB_VERSION}"
+		einfo
+
+		if [[ -n "${apu_bdb_version}" && "${SVN_BDB_VERSION}" != "${apu_bdb_version}" ]]; then
+			eerror "APR-Util is linked against Berkeley DB ${apu_bdb_version}, but you are trying"
+			eerror "to build Subversion with support for Berkeley DB ${SVN_BDB_VERSION}."
+			eerror "Rebuild dev-libs/apr-util or set SVN_BDB_VERSION=\"${apu_bdb_version}\"."
+			eerror "Aborting to avoid possible run-time crashes."
+			die "Berkeley DB version mismatch"
+		fi
+	fi
+
+	depend.apache_pkg_setup
+
+	java-pkg-opt-2_pkg_setup
+
+	if ! use webdav-neon && ! use webdav-serf; then
+		ewarn "WebDAV support is disabled. You need WebDAV to"
+		ewarn "access repositories through the HTTP protocol."
+		ewarn "Consider enabling one of the following USE-flags:"
+		ewarn "  webdav-neon webdav-serf"
+		echo -ne "\a"
+	fi
+
+	if use debug; then
+		append-cppflags -DSVN_DEBUG -DAP_DEBUG
+	fi
+
+	# Allow for custom repository locations.
+	SVN_REPOS_LOC="${SVN_REPOS_LOC:-${EPREFIX}/var/svn}"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.5.4-interix.patch \
+		"${FILESDIR}"/${PN}-1.5.6-aix-dso.patch \
+		"${FILESDIR}"/${PN}-1.6.3-hpux-dso.patch \
+		"${FILESDIR}"/${PN}-fix-parallel-build-support-for-perl-bindings.patch
+	epatch_user
+
+	fperms +x build/transform_libtool_scripts.sh
+
+	sed -i \
+		-e "s/\(BUILD_RULES=.*\) bdb-test\(.*\)/\1\2/g" \
+		-e "s/\(BUILD_RULES=.*\) test\(.*\)/\1\2/g" configure.ac
+
+	# this bites us in particular on Solaris
+	sed -i -e '1c\#!/usr/bin/env sh' build/transform_libtool_scripts.sh || \
+		die "/bin/sh is not POSIX shell!"
+
+	tc-export CC CXX
+
+	eautoconf
+	elibtoolize
+
+	sed -e 's/\(libsvn_swig_py\)-\(1\.la\)/\1-$(EPYTHON)-\2/g' \
+		-i build-outputs.mk || die "sed failed"
+
+	if use python; then
+		# XXX: make python_copy_sources accept path
+		S=${S}/subversion/bindings/swig/python python_copy_sources
+		rm -r "${S}"/subversion/bindings/swig/python || die
+	fi
+}
+
+src_configure() {
+	local myconf linkopts="" rubyopts=""
+
+	if use python || use perl || use ruby; then
+		myconf+=" --with-swig"
+	else
+		myconf+=" --without-swig"
+	fi
+
+	if use java; then
+		myconf+=" --without-junit"
+	fi
+
+	if use kde || use nls; then
+		myconf+=" --enable-nls"
+	else
+		myconf+=" --disable-nls"
+	fi
+
+	case ${CHOST} in
+		*-aix*)
+			# avoid recording immediate path to sharedlibs into executables
+			append-ldflags -Wl,-bnoipath
+		;;
+		*-darwin*)
+			# Configure says that local-library-preloading doesn't work on
+			# Darwin...
+			myconf+=" --disable-local-library-preloading"
+		;;
+		*-interix*)
+			# loader crashes on the LD_PRELOADs...
+			myconf+=" --disable-local-library-preloading"
+		;;
+		*-solaris*)
+			# need -lintl to link
+			use nls && append-libs intl
+			# this breaks installation, on x64 echo replacement is 32-bits
+			myconf+=" --disable-local-library-preloading"
+		;;
+		*-mint*)
+			myconf+=" --enable-all-static --disable-local-library-preloading"
+		;;
+		*)
+			# inject LD_PRELOAD entries for easy in-tree development
+			myconf+=" --enable-local-library-preloading"
+		;;
+	esac
+
+	#workaround for bug 387057
+	has_version =dev-vcs/subversion-1.6* && myconf+=" --disable-disallowing-of-undefined-references"
+
+	#version 1.7.7 again tries to link against the older installed version and fails, when trying to
+	#compile for x86 on amd64, so workaround this issue again
+	#check newer versions, if this is still/again needed
+	myconf+=" --disable-disallowing-of-undefined-references"
+
+	# for build-time scripts
+	if use ctypes-python || use python || use test; then
+		python_export_best
+	fi
+
+	if use clang; then
+		if type -pf python >/dev/null 2>&1; then
+			linkopts="$( python -B "${S}"/build/get-py-info.py --link )"
+			linkopts="ac_cv_python_link=\"${CC} $( echo "$link" | cut -d' ' -f 2- )\""
+		fi
+	fi
+
+	#force ruby-1.8 for bug 399105
+	#allow overriding Python include directory
+	if use ruby; then
+		rubyopts="ac_cv_path_RUBY=\"${EPREFIX}\"/usr/bin/ruby18 ac_cv_path_RDOC=\"${EPREFIX}\"/usr/bin/rdoc18"
+	fi
+
+	tc-export CC CXX
+	
+	eval \
+	ac_cv_python_compile="${CC} " \
+	ac_cv_python_includes='-I\$\(PYTHON_INCLUDEDIR\)' \
+	${linkopts} \
+	${rubyopts} \
+	econf --libdir="${EPREFIX}/usr/$(get_libdir)" \
+		$(use_with apache2 apxs "${APXS}") \
+		$(use_with berkdb berkeley-db "db.h:${EPREFIX}/usr/include/db${SVN_BDB_VERSION}::db-${SVN_BDB_VERSION}") \
+		$(use_with ctypes-python ctypesgen "${EPREFIX}/usr") \
+		$(use_enable dso runtime-module-search) \
+		$(use_with gnome-keyring) \
+		$(use_enable java javahl) \
+		$(use_with java jdk "${JAVA_HOME}") \
+		$(use_with kde kwallet) \
+		$(use_with sasl) \
+		$(use_with webdav-neon neon) \
+		$(use_with webdav-serf serf "${EPREFIX}/usr") \
+		${myconf} \
+		--with-apr="${EPREFIX}/usr/bin/apr-1-config" \
+		--with-apr-util="${EPREFIX}/usr/bin/apu-1-config" \
+		--disable-experimental-libtool \
+		--without-jikes \
+		--disable-mod-activation \
+		--disable-neon-version-check \
+		--disable-static
+}
+
+src_compile() {
+	emake local-all
+
+	if use ctypes-python; then
+		# pre-generate .py files
+		use ctypes-python && emake ctypes-python
+
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_compile
+		popd >/dev/null || die
+	fi
+
+	if use python; then
+		swig_py_compile() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			python_export PYTHON_INCLUDEDIR
+			emake swig-py \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn"
+		}
+
+		# this will give us proper BUILD_DIR for symlinking
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_compile
+	fi
+
+	if use perl; then
+		emake swig-pl
+	fi
+
+	if use ruby; then
+		emake swig-rb
+	fi
+
+	if use java; then
+		emake -j1 JAVAC_FLAGS="$(java-pkg_javac-args) -encoding iso8859-1" javahl
+	fi
+
+	if use extras; then
+		emake tools
+	fi
+
+	if use doc; then
+		doxygen doc/doxygen.conf || die "Building of Subversion HTML documentation failed"
+
+		if use java; then
+			emake doc-javahl
+		fi
+	fi
+}
+
+src_test() {
+	default
+
+	if use ctypes-python; then
+		python_test() {
+			"${PYTHON}" subversion/bindings/ctypes-python/test/run_all.py \
+				|| die "ctypes-python tests fail with ${EPYTHON}"
+		}
+
+		distutils-r1_src_test
+	fi
+
+	if use python; then
+		swig_py_test() {
+			pushd "${BUILD_DIR}" >/dev/null || die
+			"${PYTHON}" tests/run_all.py || die "swig-py tests fail with ${EPYTHON}"
+			popd >/dev/null || die
+		}
+
+		BUILD_DIR=subversion/bindings/swig/python \
+		python_foreach_impl swig_py_test
+	fi
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" local-install
+
+	if use ctypes-python; then
+		pushd subversion/bindings/ctypes-python >/dev/null || die
+		distutils-r1_src_install
+		popd >/dev/null || die
+	fi
+
+	if use python; then
+		swig_py_install() {
+			local p=subversion/bindings/swig/python
+			rm -f ${p} || die
+			ln -s "${BUILD_DIR}" ${p} || die
+
+			emake \
+				DESTDIR="${D}" \
+				swig_pydir="$(python_get_sitedir)/libsvn" \
+				swig_pydir_extra="$(python_get_sitedir)/svn" \
+				install-swig-py
+		}
+
+		BUILD_DIR=python \
+		python_foreach_impl swig_py_install
+	fi
+
+	if use perl; then
+		emake DESTDIR="${D}" INSTALLDIRS="vendor" install-swig-pl
+		fixlocalpod
+		find "${ED}" "(" -name .packlist -o -name "*.bs" ")" -delete
+	fi
+
+	if use ruby; then
+		emake DESTDIR="${D}" install-swig-rb
+	fi
+
+	if use java; then
+		emake DESTDIR="${D}" install-javahl
+		java-pkg_regso "${ED}"usr/$(get_libdir)/libsvnjavahl*$(get_libname)
+		java-pkg_dojar "${ED}"usr/$(get_libdir)/svn-javahl/svn-javahl.jar
+		rm -fr "${ED}"usr/$(get_libdir)/svn-javahl/*.jar
+	fi
+
+	# Install Apache module configuration.
+	if use apache2; then
+		keepdir "${APACHE_MODULES_CONFDIR}"
+		insinto "${APACHE_MODULES_CONFDIR}"
+		doins "${FILESDIR}/47_mod_dav_svn.conf"
+	fi
+
+	# Install Bash Completion, bug 43179.
+	newbashcomp tools/client-side/bash_completion subversion
+	rm -f tools/client-side/bash_completion
+
+	# Install hot backup script, bug 54304.
+	newbin tools/backup/hot-backup.py svn-hot-backup
+	rm -fr tools/backup
+
+	# Install svnserve init-script and xinet.d snippet, bug 43245.
+	newinitd "${FILESDIR}"/svnserve.initd2 svnserve
+	newconfd "${FILESDIR}"/svnserve.confd svnserve
+	insinto /etc/xinetd.d
+	newins "${FILESDIR}"/svnserve.xinetd svnserve
+
+	#adjust default user and group with disabled apache2 USE flag, bug 381385
+	use apache2 || sed -e "s\USER:-apache\USER:-svn\g" \
+			-e "s\GROUP:-apache\GROUP:-svnusers\g" \
+			-i "${ED}"etc/init.d/svnserve || die
+	use apache2 || sed -e "0,/apache/s//svn/" \
+			-e "s:apache:svnusers:" \
+			-i "${ED}"etc/xinetd.d/svnserve || die
+
+	# Install documentation.
+	dodoc CHANGES COMMITTERS README
+	dodoc tools/xslt/svnindex.{css,xsl}
+	rm -fr tools/xslt
+
+	# Install extra files.
+	if use extras; then
+		cat << EOF > 80subversion-extras
+PATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+ROOTPATH="${EPREFIX}/usr/$(get_libdir)/subversion/bin"
+EOF
+		doenvd 80subversion-extras
+
+		emake DESTDIR="${D}" toolsdir="/usr/$(get_libdir)/subversion/bin" install-tools || die "Installation of tools failed"
+
+		find tools "(" -name "*.bat" -o -name "*.in" -o -name ".libs" ")" -print0 | xargs -0 rm -fr
+		rm -fr tools/client-side/svnmucc
+		rm -fr tools/server-side/{svn-populate-node-origins-index,svnauthz-validate}*
+		rm -fr tools/{buildbot,dev,diff,po}
+
+		insinto /usr/share/${PN}
+		find tools -name '*.py' -exec sed -i -e '1s:python:&2:' {} + || die
+		doins -r tools
+	fi
+
+	if use doc; then
+		dohtml -r doc/doxygen/html/*
+
+		if use java; then
+			java-pkg_dojavadoc doc/javadoc
+		fi
+	fi
+
+	find "${ED}" '(' -name '*.la' ')' -print0 | xargs -0 rm -f
+
+	cd "${ED}"usr/share/locale
+	for i in * ; do
+		[[ $i == *$LINGUAS* ]] || { rm -r $i || die ; }
+	done
+}
+
+pkg_preinst() {
+	# Compare versions of Berkeley DB, bug 122877.
+	if use berkdb && [[ -f "${EROOT}usr/bin/svn" ]]; then
+		OLD_BDB_VERSION="$(scanelf -nq "${EROOT}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		NEW_BDB_VERSION="$(scanelf -nq "${ED}usr/$(get_libdir)/libsvn_subr-1$(get_libname 0)" | grep -Eo "libdb-[[:digit:]]+\.[[:digit:]]+" | sed -e "s/libdb-\(.*\)/\1/")"
+		if [[ "${OLD_BDB_VERSION}" != "${NEW_BDB_VERSION}" ]]; then
+			CHANGED_BDB_VERSION="1"
+		fi
+	fi
+}
+
+pkg_postinst() {
+	use perl && perl-module_pkg_postinst
+
+	if [[ -n "${CHANGED_BDB_VERSION}" ]]; then
+		ewarn "You upgraded from an older version of Berkeley DB and may experience"
+		ewarn "problems with your repository. Run the following commands as root to fix it:"
+		ewarn "    db4_recover -h ${SVN_REPOS_LOC}/repos"
+		ewarn "    chown -Rf apache:apache ${SVN_REPOS_LOC}/repos"
+	fi
+
+	ewarn "If you run subversion as a daemon, you will need to restart it to avoid module mismatches."
+}
+
+pkg_postrm() {
+	use perl && perl-module_pkg_postrm
+}
+
+pkg_config() {
+	# Remember: Don't use ${EROOT}${SVN_REPOS_LOC} since ${SVN_REPOS_LOC}
+	# already has EPREFIX in it
+	einfo "Initializing the database in ${SVN_REPOS_LOC}..."
+	if [[ -e "${SVN_REPOS_LOC}/repos" ]]; then
+		echo "A Subversion repository already exists and I will not overwrite it."
+		echo "Delete \"${SVN_REPOS_LOC}/repos\" first if you're sure you want to have a clean version."
+	else
+		mkdir -p "${SVN_REPOS_LOC}/conf"
+
+		einfo "Populating repository directory..."
+		# Create initial repository.
+		"${EROOT}usr/bin/svnadmin" create "${SVN_REPOS_LOC}/repos"
+
+		einfo "Setting repository permissions..."
+		SVNSERVE_USER="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_USER}")"
+		SVNSERVE_GROUP="$(. "${EROOT}etc/conf.d/svnserve"; echo "${SVNSERVE_GROUP}")"
+		if use apache2; then
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="apache"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="apache"
+		else
+			[[ -z "${SVNSERVE_USER}" ]] && SVNSERVE_USER="svn"
+			[[ -z "${SVNSERVE_GROUP}" ]] && SVNSERVE_GROUP="svnusers"
+		fi
+		chmod -Rf go-rwx "${SVN_REPOS_LOC}/conf"
+		chmod -Rf o-rwx "${SVN_REPOS_LOC}/repos"
+		echo "Please create \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Afterwards please create \"${SVNSERVE_USER}\" user with homedir \"${SVN_REPOS_LOC}\""
+		echo "and as part of the \"${SVNSERVE_GROUP}\" group if it does not exist yet."
+		echo "Finally, execute \"chown -Rf ${SVNSERVE_USER}:${SVNSERVE_GROUP} ${SVN_REPOS_LOC}/repos\""
+		echo "to finish the configuration."
+	fi
+}