add missing USE flaG

(Portage version: 2.1.6.11/cvs/Linux x86_64)

4 files changed, 132 insertions, 1 deletions

diff --git a/app-emulation/libvirt/ChangeLog b/app-emulation/libvirt/ChangeLog
index d3df498fc1fe..58a9bdd7ef07 100644
--- a/app-emulation/libvirt/ChangeLog
+++ b/app-emulation/libvirt/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.21 2009/02/20 17:47:32 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.22 2009/04/17 15:01:16 cardoe Exp $
+
+*libvirt-0.6.2 (17 Apr 2009)
+
+  17 Apr 2009; Doug Goldstein <cardoe@gentoo.org>
+  +files/libvirt-0.6.2-storage-fix.patch, +libvirt-0.6.2.ebuild:
+  version bump. ebuild is masked for evaluation. fixes bugs #256904,
+  #253961, #254568, and #249029.
 
   20 Feb 2009; Doug Goldstein <cardoe@gentoo.org> libvirt-0.4.6-r1.ebuild,
   libvirt-0.5.1.ebuild:
diff --git a/app-emulation/libvirt/files/libvirt-0.6.2-storage-fix.patch b/app-emulation/libvirt/files/libvirt-0.6.2-storage-fix.patch
new file mode 100644
index 000000000000..e3eeda1fe2b8
--- /dev/null
+++ b/app-emulation/libvirt/files/libvirt-0.6.2-storage-fix.patch
@@ -0,0 +1,11 @@
+--- src/storage_backend_fs.c.old	2009-04-03 14:57:21.000000000 -0500
++++ src/storage_backend_fs.c	2009-04-03 14:57:54.000000000 -0500
+@@ -1152,7 +1152,7 @@
+                                   vol->target.format);
+             return -1;
+         }
+-        if (vol->backingStore.path != NULL) {
++        if (vol->target.path != NULL) {
+             virStorageReportError(conn, VIR_ERR_NO_SUPPORT,
+                                   _("copy-on-write image not supported with "
+                                     "qcow-create"));
diff --git a/app-emulation/libvirt/libvirt-0.6.2.ebuild b/app-emulation/libvirt/libvirt-0.6.2.ebuild
new file mode 100644
index 000000000000..ee1a15697146
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-0.6.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.2.ebuild,v 1.1 2009/04/17 15:01:16 cardoe Exp $
+
+EAPI=1
+
+inherit eutils autotools
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="http://www.libvirt.org/"
+SRC_URI="http://libvirt.org/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="avahi iscsi hal kvm lvm +lxc +network openvz parted qemu sasl selinux uml xen"
+# policykit is in package.mask
+# devicekit isn't in portage
+
+DEPEND="sys-libs/readline
+	sys-libs/ncurses
+	>=dev-libs/libxml2-2.5
+	>=net-libs/gnutls-1.0.25
+	dev-lang/python
+	sys-fs/sysfsutils
+	net-analyzer/netcat
+	dev-util/pkgconfig
+	avahi? ( >=net-dns/avahi-0.6 )
+	iscsi? ( sys-block/open-iscsi )
+	kvm? ( app-emulation/kvm )
+	lvm? ( sys-fs/lvm2 )
+	network? ( net-misc/bridge-utils net-dns/dnsmasq net-firewall/iptables )
+	openvz? ( sys-kernel/openvz-sources )
+	parted? ( >=sys-apps/parted-1.8 )
+	qemu? ( app-emulation/qemu )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( sys-libs/libselinux )
+	xen? ( app-emulation/xen-tools app-emulation/xen )
+	"
+	#policykit? ( >=sys-auth/policykit-0.6 )
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/"${PN}"-0.4.6-qemu-img-name.patch
+	epatch "${FILESDIR}"/"${P}"-storage-fix.patch
+	eautoreconf
+}
+
+pkg_setup() {
+	local hasbackend=0
+	local backends="lxc kvm openvz qemu uml xen"
+	local backend
+
+	for backend in $backends ; do
+		use $backend && hasbackend=1
+	done
+
+	if [ "$hasbackend" == 0 ]; then
+		local msg="You must enable one of these USE flags: $backends"
+		eerror "$msg"
+		die "$msg"
+	fi
+}
+
+src_compile() {
+	local my_conf=""
+	if use qemu || use kvm ; then
+		# fix path for kvm-img but use qemu-img if the useflag is set
+		my_conf="--with-qemu \
+			$(use_with !qemu qemu-img-name kvm-img)"
+	else
+		my_conf="--without-qemu"
+	fi
+
+	econf \
+		$(use_with avahi) \
+		$(use_with iscsi storage-iscsi) \
+		$(use_with lvm storage-lvm) \
+		$(use_with lxc) \
+		$(use_with hal) \
+		$(use_with openvz) \
+		$(use_with parted storage-disk) \
+		$(use_with sasl) \
+		$(use_with selinux) \
+		$(use_with uml) \
+		$(use_with xen) \
+		$(use_with network) \
+		${my_conf} \
+		--without-devkit \
+		--without-polkit \
+		--with-remote \
+		--disable-iptables-lokkit \
+		--localstatedir=/var \
+		--with-remote-pid-file=/var/run/libvirtd.pid \
+		|| die "econf failed"
+		#$(use_with policykit) \
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}
+	newinitd "${FILESDIR}"/libvirtd.init libvirtd
+	newconfd "${FILESDIR}"/libvirtd.confd libvirtd
+}
+
+pkg_postinst() {
+	elog "To allow normal users to connect to libvirtd you must change the"
+	elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
+}
diff --git a/app-emulation/libvirt/metadata.xml b/app-emulation/libvirt/metadata.xml
index af2f2fe40bda..e516b1b3e8a2 100644
--- a/app-emulation/libvirt/metadata.xml
+++ b/app-emulation/libvirt/metadata.xml
@@ -28,5 +28,6 @@
 			virtual machines</flag>
 		<flag name='xen'>Add support for <pkg>app-emulation/xen</pkg> based
 			virtual machines</flag>
+		<flag name='network'>Enable networking support for guests</flag>
 	</use>
 </pkgmetadata>