media-libs/lilv: bump to 0.24.22 + py3.12

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 78 insertions, 1 deletions

diff --git a/media-libs/lilv/Manifest b/media-libs/lilv/Manifest
index 33dfd78056d0..b7144c8eebd5 100644
--- a/media-libs/lilv/Manifest
+++ b/media-libs/lilv/Manifest
@@ -1 +1,2 @@
 DIST lilv-0.24.20.tar.xz 118460 BLAKE2B 50b2044a7fb62cfcbea6dc68cd0d26503780f30a5a04e2ceafca9e02b2369965d7d27b8d08bbfa136930a3b18a3e0eb6cf4c326d3c2d46218badb4a8ec6e1e01 SHA512 68963b66fd6e577280867fcd5a601fd2cf539a10fcf0b667c22165cc7e42206fd6a20d56dbe97b587fb68f798d4db3b2351b87b1243c665c3a2b1bb82cbbf9a3
+DIST lilv-0.24.22.tar.xz 105504 BLAKE2B bd9df20d95ffa921615fb21deed4bc354158219aa51125fc00351aa5ca2f480f9d10d8c867003a373b47eea145c21bb8d0bfc86d53eb1d04d281e1df2fc4a0f2 SHA512 cd771db89919a11e258d12b43674d7174645a4369f5d3a5168b1217c0a87795926dd7db5304e81cb27eb30477198ac42e6e4931d40fcda833bf70ef75acc558f
diff --git a/media-libs/lilv/lilv-0.24.20-r1.ebuild b/media-libs/lilv/lilv-0.24.20-r1.ebuild
index bbf5a2b99f95..cbde1c693833 100644
--- a/media-libs/lilv/lilv-0.24.20-r1.ebuild
+++ b/media-libs/lilv/lilv-0.24.20-r1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{9..12} )
 PYTHON_REQ_USE='threads(+)'
 
 inherit meson-multilib python-single-r1
diff --git a/media-libs/lilv/lilv-0.24.22.ebuild b/media-libs/lilv/lilv-0.24.22.ebuild
new file mode 100644
index 000000000000..b8a215c8d607
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.22.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit meson-multilib python-single-r1
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="https://drobilla.net/software/lilv.html"
+SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc python test tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx-lv2-theme
+		dev-python/sphinxygen
+	)
+"
+# Take care on bumps to check minimum versions!
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/serd[${MULTILIB_USEDEP}]
+	>=dev-libs/sord-0.16.16[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	media-libs/lv2[${MULTILIB_USEDEP}]
+	media-libs/sratom[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s/versioned_name/'${PF}'/g" doc/html/meson.build doc/singlehtml/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature python bindings_py)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+	python_optimize
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+
+	newenvd - 60lv2 <<-EOF
+		LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
+	EOF
+}